如何判断变量在Perl中是否具有数值?

时间:2008-08-15 19:43:15

标签: perl numbers

在Perl中是否有一种简单的方法可以让我确定给定的变量是否为数字?有点像:

if (is_number($x))
{ ... }

会很理想。当使用-w开关时不会抛出警告的技术当然是首选。

15 个答案:

答案 0 :(得分:119)

使用Scalar::Util::looks_like_number()使用内部Perl C API的look_like_number()函数,这可能是最有效的方法。 请注意,字符串“inf”和“infinity”被视为数字。

实施例

#!/usr/bin/perl

use warnings;
use strict;

use Scalar::Util qw(looks_like_number);

my @exprs = qw(1 5.25 0.001 1.3e8 foo bar 1dd inf infinity);

foreach my $expr (@exprs) {
    print "$expr is", looks_like_number($expr) ? '' : ' not', " a number\n";
}

给出这个输出:

1 is a number
5.25 is a number
0.001 is a number
1.3e8 is a number
foo is not a number
bar is not a number
1dd is not a number
inf is a number
infinity is a number

另见:

答案 1 :(得分:23)

查看CPAN模块Regexp::Common。我认为它完全符合您的需要并处理所有边缘情况(例如实数,科学记数法等)。 e.g。

use Regexp::Common;
if ($var =~ /$RE{num}{real}/) { print q{a number}; }

答案 2 :(得分:21)

最初的问题是如何判断变量是否为数字,而不是“是否具有数值”。

有一些运算符对数字和字符串操作数具有单独的操作模式,其中“数字”表示最初为数字或曾在数字上下文中使用的任何操作(例如,在$x = "123"; 0+$x之前,另外,$x是一个字符串,之后它被认为是数字的。)

一种说法是:

if ( length( do { no warnings "numeric"; $x & "" } ) ) {
    print "$x is numeric\n";
}

答案 3 :(得分:8)

问题的一个简单(也许是简单的)答案是$x数字的内容如下:

if ($x  eq  $x+0) { .... }

它对原始$x与转换为数字值的$x进行了文字比较。

答案 4 :(得分:7)

通常使用正则表达式进行数字验证。此代码将确定某些内容是否为数字以及检查未定义的变量以便不抛出警告:

sub is_integer {
   defined $_[0] && $_[0] =~ /^[+-]?\d+$/;
}

sub is_float {
   defined $_[0] && $_[0] =~ /^[+-]?\d+(\.\d+)?$/;
}

这是你应该看的一些reading material

答案 5 :(得分:3)

不完美,但你可以使用正则表达式:

sub isnumber 
{
    shift =~ /^-?\d+\.?\d*$/;
}

答案 6 :(得分:3)

我不相信有任何内置的东西可以做到。如果您想了解更多关于此主题的信息,请参阅Perlmonks on Detecting Numeric

答案 7 :(得分:2)

rexep不完美......这是:

use Try::Tiny;

sub is_numeric {
  my ($x) = @_;
  my $numeric = 1;
  try {
    use warnings FATAL => qw/numeric/;
    0 + $x;
  }
  catch {
    $numeric = 0;
  };
  return $numeric;
}

答案 8 :(得分:2)

Regexp::Common中可以找到更强大的正则表达式。

听起来你想知道Perl是否认为变量是数字。这是一个捕获该警告的函数:

sub is_number{
  my $n = shift;
  my $ret = 1;
  $SIG{"__WARN__"} = sub {$ret = 0};
  eval { my $x = $n + 1 };
  return $ret
}

另一种选择是在本地关闭警告:

{
  no warnings "numeric"; # Ignore "isn't numeric" warning
  ...                    # Use a variable that might not be numeric
}

请注意,非数字变量将以静默方式转换为0,这可能是您想要的。

答案 9 :(得分:1)

试试这个:

If (($x !~ /\D/) && ($x ne "")) { ... }

答案 10 :(得分:1)

我发现这很有意思

if ( $value + 0 eq $value) {
    # A number
    push @args, $value;
} else {
    # A string
    push @args, "'$value'";
}

答案 11 :(得分:0)

就我个人而言,我认为要走的路是依靠Perl的内部环境来使解决方案具有防弹性。一个好的正则表达式可以匹配所有有效的数值而不是非数字值(反之亦然),但是由于有一种方法可以使用相同的逻辑,解释器使用它应该更安全,直接依赖它。 / p>

由于我倾向于使用-w运行我的脚本,所以我必须结合比较"值加零"的结果。使用基于no warnings的@ysth方法:

的原始值
do { 
    no warnings "numeric";
    if ($x + 0 ne $x) { return "not numeric"; } else { return "numeric"; }
}

答案 12 :(得分:0)

您可以使用正则表达式来确定$ foo是否为数字。

看看这里: How do I determine whether a scalar is a number

答案 13 :(得分:-1)

if(定义$ x&& $ x!~m / \ D /){} 要么 $ x = 0如果! $ X; if($ x!~m / \ D /){}

这是Veekay的回答略有不同,但让我解释一下我改变的理由。

对未定义的值执行正则表达式将导致错误喷出,并且会导致代码在许多(如果不是大多数)环境中退出。测试值是否已定义或设置默认情况,就像我在替代示例中所做的那样,在运行表达式之前,至少会保存错误日志。

答案 14 :(得分:-1)

这个功能对我有用:

    sub IS_Integer() 
    {
        my $Text = shift;
        my $Integer = 0;

        if ($Text =~ /\D/)
        {
            $Integer = 1;
        }
        if ($Text =~ /^\d+$/)
        { 
            $Integer = 1;
        }
        if ($Text =~ /^-?\d+$/)       
        { 
            $Integer = 1;
        }
        if ($Text =~ /^[+-]?\d+$/)    
        { 
            $Integer = 1; 
        }
        if ($Text =~ /^-?\d+\.?\d*$/) 
        {
            $Integer = 1; 
        }
        if ($Text =~ /^-?(?:\d+(?:\.\d*)?&\.\d+)$/) 
        {
            $Integer = 1;
        }
        if ($Text =~ /^([+-]?)(?=\d&\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/)
        {
            $Integer = 1;
        }

        return $Integer;
    }