Question

我正在使用ANTLR指定包含不超过254个字符的行的文件格式（不包括行结尾）。如何在语法中对此进行编码，但不做：

line : CHAR? CHAR? CHAR? CHAR? ... (254 times)

Answer 1

可以使用semantic predicate来处理。

首先写下你的语法，使你的行数不再重要。一个例子如下：

grammar Test;

parse
  :  line* EOF
  ;

line
  :  Char+ (LineBreak | EOF)
  |  LineBreak // empty line!
  ;

LineBreak : '\r'? '\n' | '\r' ;
Char      : ~('\r' | '\n') ;

然后将“谓词”添加到line规则：

grammar Test;

@parser::members {
    public static void main(String[] args) throws Exception {
        String source = "abcde\nfghij\nklm\nnopqrst";
        ANTLRStringStream in = new ANTLRStringStream(source);
        TestLexer lexer = new TestLexer(in);
        CommonTokenStream tokens = new CommonTokenStream(lexer);
        TestParser parser = new TestParser(tokens);
        parser.parse();
    }  
}

parse
  :  line* EOF
  ;

line
  :  (c+=Char)+ {$c.size()<=5}? (LineBreak | EOF)
  |  LineBreak // empty line!
  ;

LineBreak : '\r'? '\n' | '\r' ;
Char      : ~('\r' | '\n') ;

c+=Char将构造一个包含该行中所有字符的ArrayList。当{$c.size()<=5}?的大小超过5时，ArrayList会导致异常。

我还在解析器中添加了一个main方法，以便您自己测试它：

// *nix/MacOSX
java -cp antlr-3.2.jar org.antlr.Tool Test.g
javac -cp antlr-3.2.jar *.java
java -cp .:antlr-3.2.jar TestParser

// Windows
java -cp antlr-3.2.jar org.antlr.Tool Test.g
javac -cp antlr-3.2.jar *.java
java -cp .;antlr-3.2.jar TestParser

将输出：

line 0:-1 rule line failed predicate: {$c.size()<=5}?

HTH

在ANTLR中，如何指定特定的重复次数？

1 个答案: