Question

给出以下XML：

<test id="s1-t2" name="Lorem ipsum">
    ...
    <tags>
        <tag>foo</tag>
        <tag>bar</tag>
    </tags>
    ...
</test>

我想在test元素的name属性中追加每个tag元素的节点值。所以生成的XML应该是这样的：

<test id="s1-t2" name="Lorem ipsum [foo][bar]">
    ...
    <tags>
        <tag>foo</tag>
        <tag>bar</tag>
    </tags>
    ...
</test>

标签元素（及其内容）可以保留在原位，但不是必需的。

到目前为止，我尝试过这样的事情：

<xsl:template match="test">
    <test>
        <xsl:copy-of select="@*"/>
        <xsl:attribute name="name">
            <xsl:value-of select="tags/tag"/>
        </xsl:attribute>
        <xsl:apply-templates select="node()"/>
    </test>
</xsl:template>

但这不起作用。即使它可以工作，它也会替换name属性，只能用一个标签。自从我上次写任何XSLT以来已经太久了。

Answer 1

我想在名称中附加每个标记元素的节点值测试元素的属性。

以这种方式尝试：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="/test/@name">
    <xsl:attribute name="name">
        <xsl:value-of select="."/>
        <xsl:for-each select="../tags/tag">
            <xsl:text>[</xsl:text>
            <xsl:value-of select="."/>
            <xsl:text>]</xsl:text>
        </xsl:for-each>
    </xsl:attribute>
</xsl:template>

</xsl:stylesheet>

XSL将孙子节点值转换为元素属性值

1 个答案: