Question

我正在尝试在我的Workflow脚本中包含外部代码，但我遗漏了一些东西。第一步似乎有效。如果路径无效，则失败：

evaluate( new File('/home/larry.fast/Wkflo.groovy'))

但我在下面尝试了一些语法变体，并没有找到有效的咒语。所有尝试都产生了“无法解析类mycode.Wkflo。

的变体

def z = mycode.Wkflo()

Wkflo.groovy包含：

package mycode;
def hello() {
  echo "Hello from workflow"
}

我也尝试过像run（File（））或删除包声明这样的变体。

Answer 1

Jenkins Workflow文档现在包含“加载脚本文本”部分 https://github.com/jenkinsci/workflow-plugin/blob/master/TUTORIAL.md但我发现很难遵循。这是一个简单的示例，演示了如何在外部文件中创建完整的工作流程和其他方法。

Jenkins中的工作流程代码：

// Loading code requires a NODE context
// But we want the code accessible outside the node Context
// So declare extcode (object created by the LOAD operation) outside the Node block.
def extcode 

node {
    // paths are relative to your workspace
    // you may need to run git to populate your workspace
    git url: 'ssh://mygitrepo'
    extcode = load 'myExtCode.wkflo'

    // or you can directly access the file system
    // Eg. when developing your code in a local git clone
    extcode = load '/some/absolute/path/myExtCode.wkflo'

    // extcode is now a groovy object containing everything declared in the file
    extcode.hello('world')
}
// If your code contains Stage and Node blocks, 
// you'll want to initiate that code outside of the node() block above
extcode.extMain()

------ myExtCode.wkflo

// Any command placed at the root of the file get executed during the load operation
echo "hello from loading myExtCode"

// Methods declared in external code are accessible
//   directly from other code in the external file
//   indirectly via the object created by the load operation
//   eg.  extcode.hello('use this syntax from your main code')
def hello(whom) {
    echo "Hello ${whom}"
}

// Complete workflows should be created inside a controlling method
// else they will run nested inside the node() block when the load takes place (edit: added missing "def" keyword
def extMain() {
    stage 'External Code is running'
    node() {
        hello('from external node block')
    }
}

// !!Important Boilerplate!!     
// The external code must return it's contents as an object
return this;

如何在Jenkins Workflow中包含外部代码文件

1 个答案: