Question

我正在尝试做一些非常简单的事情：给一堆精灵制作动画，这样无论他们在舞台上的哪个位置，他们都会朝着一个点（在这种情况下，舞台的中心）。 / p>

它只适用于其中一些。他们中的一些人只是坐在那里。我无法弄清楚为什么。我认为它与atan2以及我使用它的方式有关，但我不确定是什么。有人能看到吗？

谢谢，

大卫

package
{

import Ball;

import flash.display.Sprite;
import flash.display.StageAlign;
import flash.display.StageScaleMode;
import flash.events.Event;

public class MoveBalls extends Sprite {

    private var balls:Array = new Array();
    private var speed:Number = new Number(10);

    public function MoveBalls() {
        init();
    }

    private function init():void {
        stage.align = StageAlign.TOP_LEFT;
        stage.scaleMode = StageScaleMode.NO_SCALE;

        for(var i:int = 0; i<30; i++)
        {
            var ball:Ball = new Ball(20);
            ball.x = getRandomNumber();
            if(ball.x > stage.stageWidth) ball.x = stage.stageWidth -10;
            if(ball.x < 0) ball.x = 10;
            trace(ball.x);
            ball.y = getRandomNumber();
            if(ball.y >stage.stageHeight) ball.y = stage.stageHeight - 10;
            if(ball.y < 0) ball.y = 10;
            addChild(ball);
            balls.push(ball);
        }

        addEventListener(Event.ENTER_FRAME, onEnterFrame);
    }

    private function getRandomNumber():Number {
        var decider:Number = Math.random();
        if (decider < 0.5) {
            return Math.random()*1000;
        } else {
            return Math.random()*-1000;
        }
    }

    public function onEnterFrame(event:Event):void {

        var targetX:Number = stage.stageWidth/2;
        var targetY:Number = stage.stageHeight/2;
        for(var i:int=0; i < balls.length; i++)
        {
            var startX:Number = balls[i].x;
            var startY:Number = balls[i].y;
            var atanX:Number = (targetX - startX);
            var atanY:Number = (targetY - startY);
            if(atanX > .1)   //just stop when it's close enough to the center
            {
                var ang:Number  = Math.atan2(atanY, atanX);
                var xSpeed:Number = Math.cos(ang)*speed;
                var ySpeed:Number = Math.sin(ang)*speed;
                balls[i].x += xSpeed;
                balls[i].y += ySpeed;
            }
        }

    }
}
}

//ball class
package {
import flash.display.Sprite;

public class Ball extends Sprite {
    private var radius:Number;
    private var color:uint;

    public function Ball(radius:Number=40, color:uint=0xff0000) {
        this.radius = radius;
        this.color = color;
        init();
    }
    public function init():void {
        graphics.beginFill(color);
        graphics.drawCircle(0, 0, radius);
        graphics.endFill();
    }
}
}

Answer 1

我不同意这句话：

if(atanX > .1)

因为如果球要进入舞台的中心，就像在X轴和Y轴上一样，那么对于直接位于中心下方或上方的球，这种情况就会失败。

像这样做

 if (atanX > .1 || atanY > .1)

=如果差异中的任何一个大于.1，请继续使用atan2 ...

编辑：一个更明显的错误 - atanX或atanY变量可以在50％中为负数。因此，请使用以下任何一个：

if (Math.abs(atanX) > .1 || Math.abs(atanY) > .1)

或者这个，但是相同但更快（虽然难以阅读）：

if ((atanX > 0 ? atanX : -atanX) > .1 || (atanY > 0 ? atanY : -atanY) > .1)

将精灵动画化为一个点

1 个答案: