替代方法：带接口的MSL样式

Question

我正在尝试建立一个模型，该模型可以在相同的范围内使用两个不同的组件（从现有库中获取）：特别是带有热交换器的系统；该热交换器可以基于不同的技术，例如管道或板块。

然后我想用一个默认的可替换交换器定义一个模型，并说出可以使用哪些其他技术。

这是我尝试过的简单示例：

package Test

  // Component 1 original definition in the library
  model COMP1
    parameter Real p1=1 "";
    Real v "";
  equation 
    v=p1*time;
  end COMP1;

  // Component 2 original definition in the library
  model COMP2
    parameter Real p2=1 "";
    Real v "";
  equation 
    v=p2*time;
  end COMP2;

  // Main module (system)
  model MAIN
    parameter Real pm=100 "";
    Real vm "";

    // Redefinition of the component modifing the default values
    model call1 = COMP1(p1=10);
    model call2 = COMP2(p2=20);

    replaceable call1 OBJ
    annotation(choices(
            choice(redeclare call1 OBJ "Default"),
            choice(redeclare call2 OBJ "Variant")));

  equation 
    vm = OBJ.v+pm;
  end MAIN;

  // Application model, using the main model
  model APP
    MAIN mAIN;
  end APP;

end Test;

模型APP成功运行。但是，如果我打开APP.mAIN的参数并更改OBJ（选择“默认”或“变体”），则会导致修改APP模型的步骤如下：

  model APP
    MAIN mAIN(redeclare call1 OBJ "Default");
  end APP;

我收到以下错误：

Component type specifier call1 not found

我不明白自己做错了什么，请帮忙。

Answer 1

发生与错误相关的问题，因为您没有在选择注释中使用正确的类路径。

如果您在APP中选择“默认”，则会得到以下代码：

model APP
  MAIN mAIN(redeclare call1 OBJ "Default");
end APP;

在这里我们看到类路径call1无效。 APP只能使用相对类路径call1或绝对类路径MAIN.call1来访问Test.MAIN.call1。因此，您可以使用以下注释解决此问题：

  replaceable call1 OBJ
  annotation(choices(
          choice(redeclare MAIN.call1 OBJ "Default"),
          choice(redeclare MAIN.call2 OBJ "Variant")));

但是，在Dymola中，由于MAIN中的本地类定义，在修改默认值的组件的定义下下，该模型仍然无法检查。在这里，您将创建新的类call1和call2。这可能是Dymola错误，因为它可以在OpenModelica中使用-但是新类不是必需的。相反，您可以使用原始类，并在redeclare语句中使用修饰符方程式设置参数，如下所示：

model MAIN
  parameter Real pm=100 "";
  Real vm "";

  replaceable COMP1 OBJ
  annotation(choices(
          choice(redeclare Test.COMP1 OBJ(p1=10) "Default"),
          choice(redeclare Test.COMP2 OBJ(p2=10) "Variant")));
equation 
  vm = OBJ.v+pm;
end MAIN;

现在，该模型无法选择并且使用“默认”，但是当选择“变体”时，Dymola抱怨重新声明的类不包含与原始类相同的变量。这是使用可替换类时的限制之一（同样，OpenModelica没问题，但是Dymola警告您这不符合Modelica语言规范）

替代方法：带接口的MSL样式

我建议像Modelica库一样创建一个接口模型（例如，使用Modelica.Electrical.Analog.Interfaces.OnePort）：

您创建一个partial基本模型，其中包含所有所有变体（称为接口）的所有内容
这些变体扩展了现有库的接口和模型之一
使用变体的类实例化一个变体，并使用constrainedby将限制重新定义为接口
您现在可以使用注释choicesAllMatching自动创建它，而不是手动创建choice注释

这是您的示例的样子。第三方组件COMP1和COMP2已移至包ReadOnlyLibrary。

package Test
  // Original definition of Component 1 and 2 in the external library
  package ReadOnlyLibrary
    model COMP1
      parameter Real p1=1 "";
      Real v "";
    equation 
      v=p1*time;
    end COMP1;

    model COMP2
      parameter Real p2=1 "";
      Real v "";
    equation 
      v=p2*time;
    end COMP2;
  end ReadOnlyLibrary;

  // Interface and variants with modified default values
  partial model Call_Interface
    Real v "";
  end Call_Interface;

  model Call1 "Default"
    extends Call_Interface;
    extends ReadOnlyLibrary.COMP1(p1=10);
  end Call1;

  model Call2 "Variant"
    extends Call_Interface;
    extends ReadOnlyLibrary.COMP2(p2=20);
  end Call2;

  // Main module (system)
  model Main
    parameter Real pm=100 "";
    Real vm "";

    replaceable Test.Call1 OBJ constrainedby Test.Call_Interface annotation (choicesAllMatching);

  equation 
    vm = OBJ.v+pm;
  end Main;

  // Application model, using the main model
  model App
    Main main annotation (Placement(transformation(extent={{-12,10},{8,30}})));
  end App;
end Test;

Modelica：如何使用可更换组件？

1 个答案:

替代方法：带接口的MSL样式