Question

Gday All，

我最近一直在涉及一些F＃，我想出了一些我从一些C＃代码中移植的字符串构建器。它将对象转换为字符串，前提是它传递了属性中定义的正则表达式。它可能对手头的任务有些过分，但出于学习目的。

目前，BuildString成员使用可变字符串变量updatedTemplate。我一直绞尽脑汁去研究这样做，没有任何可变对象也无济于事。这让我想到了我的问题。

是否可以在没有任何可变对象的情况下实现BuildString成员函数？

干杯，

迈克尔

//The Validation Attribute
type public InputRegexAttribute public (format : string) as this =
    inherit Attribute()
    member self.Format with get() = format

//The class definition
type public Foo public (firstName, familyName) as this =
    [<InputRegex("^[a-zA-Z\s]+$")>]
    member self.FirstName with get() = firstName 

    [<InputRegex("^[a-zA-Z\s]+$")>]
    member self.FamilyName with get() = familyName 

module ObjectExtensions =
    type System.Object with
        member this.BuildString template =
            let mutable updatedTemplate : string  = template
            for prop in this.GetType().GetProperties() do
                for attribute in prop.GetCustomAttributes(typeof<InputRegexAttribute>,true).Cast<InputRegexAttribute>() do
                    let regex = new Regex(attribute.Format)
                    let value = prop.GetValue(this, null).ToString()
                    if regex.IsMatch(value) then
                        updatedTemplate <- updatedTemplate.Replace("{" + prop.Name + "}", value)
                    else
                        raise (new Exception "Regex Failed")
            updatedTemplate

open ObjectExtensions
try
    let foo = new Foo("Jane", "Doe")
    let out = foo.BuildInputString("Hello {FirstName} {FamilyName}! How Are you?")
    printf "%s" out
with | e -> printf "%s" e.Message

Answer 1

我没有时间把它写成代码，但是：

写一个代表最里面部分的函数，取一个字符串（到目前为止的结果）和属性和属性的元组，并在替换后返回字符串。
使用seq.map_concat从GetProperties()返回的属性数组转到（属性，属性）元组序列。
使用前两位seq.fold进行整个转换，使用原始模板作为聚合的初始值。整体结果将是最终替换的字符串。

这有意义吗？

Answer 2

我认为你总是可以将“只有一个效果的序列的for循环（变换一个局部变量）”变换成去掉变量的代码;这是一般变换的一个例子：

let inputSeq = [1;2;3]

// original mutable
let mutable x = ""
for n in inputSeq do
    let nStr = n.ToString()
    x <- x + nStr
printfn "result: '%s'" x

// immutable
let result = 
    inputSeq |> Seq.fold (fun x n ->
        // the 'loop' body, which returns
        // a new value rather than updating a mutable
        let nStr = n.ToString()
        x + nStr
    ) ""  // the initial value
printfn "result: '%s'" result

您的特定示例具有嵌套循环，因此这是一个通过两个步骤显示相同类型的机械变换的示例：

let inputSeq1 = [1;2;3]
let inputSeq2 = ["A";"B"]

let Original() = 
    let mutable x = ""
    for n in inputSeq1 do
        for s in inputSeq2 do
            let nStr = n.ToString()
            x <- x + nStr + s
    printfn "result: '%s'" x

let FirstTransformInnerLoopToFold() = 
    let mutable x = ""
    for n in inputSeq1 do
        x <- inputSeq2 |> Seq.fold (fun x2 s ->
            let nStr = n.ToString()
            x2 + nStr + s
        ) x
    printfn "result: '%s'" x

let NextTransformOuterLoopToFold() = 
    let result = 
        inputSeq1 |> Seq.fold (fun x3 n ->
            inputSeq2 |> Seq.fold (fun x2 s ->
                let nStr = n.ToString()
                x2 + nStr + s
            ) x3
        ) ""
    printfn "result: '%s'" result

（在上面的代码中，我使用名称'x2'和'x3'来使范围更明显，但你可以在整个过程中使用'x'这个名称。）

尝试对您的示例代码执行相同的转换并发布您自己的答案可能是值得的。这不一定会产生最惯用的代码，但可以是将for循环转换为Seq.fold调用的练习。

（也就是说，在这个例子中，整个目标主要是学术练习 - 具有可变性的代码是'很好'。）

Answer 3

一种纯粹的功能性方法：

module ObjectExtensions =
type System.Object with
    member this.BuildString template =
        let properties = Array.to_list (this.GetType().GetProperties())
        let rec updateFromProperties (pps : Reflection.PropertyInfo list) template =
            if pps = List.Empty then
                template
            else 
                let property = List.hd pps
                let attributes = Array.to_list (property.GetCustomAttributes(typeof<InputRegexAttribute>,true))
                let rec updateFromAttributes (ats : obj list) (prop : Reflection.PropertyInfo) (template : string) =
                    if ats = List.Empty then
                        template
                    else
                        let a = (List.hd ats) :?> InputRegexAttribute
                        let regex = new Regex(a.Format)
                        let value = prop.GetValue(this, null).ToString()
                        if regex.IsMatch(value) then
                            template.Replace("{" + prop.Name + "}", value)
                        else
                            raise (new Exception "Regex Failed\n")
                updateFromProperties(List.tl pps) (updateFromAttributes attributes property template)
        updateFromProperties properties template

F＃可变为不可变

3 个答案: