Question

我需要使用XSLT创建“组组”。

以下是我的XML和XSL文件。我用这个SO link来应用Muenchian分组。我试图缩短文件并仅显示代表问题的必需元素。

XML文件

<IO_SearchShoppingFilesResult xmlns="http://schemas.datacontract.org/2004/07/Trevoo.WS.IO.Shopping" xmlns:i="http://www.w3.org/2001/XMLSchema-instance">
<ShoppingFiles
 xmlns:a="http://schemas.datacontract.org/2004/07/Trevoo.WS.Entities.Shopping"
 xmlns:b="http://schemas.datacontract.org/2004/07/Trevoo.WS.Entities.Air">
    <a:T_ShoppingFile>
        ....
        <b:T_AirBookingItem>
            ...
            <a:LocalPaxType>ADT</a:LocalPaxType>
            ...
        </b:T_AirBookingItem>
        <b:T_AirBookingItem>
            ...
            <a:LocalPaxType>CHD</a:LocalPaxType>
            ...
        </b:T_AirBookingItem>
        <b:T_AirBookingItem>
            ...
            <a:LocalPaxType>INF</a:LocalPaxType>
            ...
        </b:T_AirBookingItem>
        ...
    </a:T_ShoppingFile>

    <a:T_ShoppingFile>
        ....
        <b:T_AirBookingItem>
            ...
            <a:LocalPaxType>ADT</a:LocalPaxType>
            ...
        </b:T_AirBookingItem>
        ...
    </a:T_ShoppingFile>
</ShoppingFiles>
</IO_SearchShoppingFilesResult>

XSL文件

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:res="http://schemas.datacontract.org/2004/07/Trevoo.WS.IO.Shopping"
xmlns:a="http://schemas.datacontract.org/2004/07/Trevoo.WS.Entities.Shopping"
xmlns:b="http://schemas.datacontract.org/2004/07/Trevoo.WS.Entities.Air"
xmlns:c="http://schemas.microsoft.com/2003/10/Serialization/Arrays"
xmlns:bb="http://schemas.datacontract.org/2004/07/Trevoo.WS.Entities.Shopping.Views">
<xsl:output method="xml" indent="yes" />


<xsl:key name="travelerGroup"
    match="res:IO_SearchShoppingFilesResult/res:ShoppingFiles/a:T_ShoppingFile[position()=1]/a:AirBookings/b:T_AirBooking/b:BookingItems/b:T_AirBookingItem"
    use="b:PaxReference/a:LocalPaxType" />

<xsl:template match="/">
    <xsl:element name="PNRViewRS">
        <xsl:apply-templates
            select="res:IO_SearchShoppingFilesResult/res:ShoppingFiles" />
    </xsl:element>      
</xsl:template>

<xsl:template match="res:ShoppingFiles">
    <!-- For FareGroup, Traveler, Telephone, EmailAddress -->
    <xsl:apply-templates select="a:T_ShoppingFile" />
    ...
</xsl:template>

<xsl:template match="a:T_ShoppingFile">
    ...
    <xsl:apply-templates
            select="a:AirBookings/b:T_AirBooking/b:BookingItems/b:T_AirBookingItem[generate-id() = generate-id(key('travelerGroup', b:PaxReference/a:LocalPaxType)[1])]" />
    ...
</xsl:template>
...
<xsl:template match="b:T_AirBookingItem">
    ...
                    <!-- Line 1 -->
        <xsl:value-of
            select="count(key('travelerGroup', b:PaxReference/a:LocalPaxType))" />  
    ...

</xsl:template>

如我所见，我已在key上应用了<b:T_AirBookingItem>。多个<b:T_AirBookingItem>中存在多个<a:T_ShoppingFile>。

现在，我想分别处理每个<a:T_ShoppingFile>，然后对其中的所有<b:T_AirBookingItem>应用分组。此代码中的内容是，所有<b:T_AirBookingItem>中的所有<a:T_ShoppingFile>都会一次归为一组。

第1行显示了此转换的结果之一。它应该显示单个<b:T_AirBookingItem> 的特定<a:LocalPaxType>（例如ADT）的<a:T_ShoppingFile>总数。但是，它会考虑整个XML中的所有<b:T_AirBookingItem>。

所以我应该得到“1”个ADT，我得到“2”。

我该如何处理？

Answer 1

听起来您想要使用由多个元素组成的复合键。在这种情况下，你正在通过 a：T_ShoppingFile 和 a：LocalPaxType 进行搜索，所以你可能需要这样的东西

<xsl:key 
   name="item" 
   match="b:T_AirBookingItem" 
   use="concat(generate-id(..) , '|', a:LocalPaxType)" />

然后，为每个 a：T_ShoppingFile 获取唯一的 a：LocalPaxType 记录，您只需执行此操作

<xsl:apply-templates 
  select="b:T_AirBookingItem[generate-id() 
    = generate-id(key('item', concat(generate-id(..) , '|', a:LocalPaxType))[1])]" />

这是完整的XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:res="http://schemas.datacontract.org/2004/07/Trevoo.WS.IO.Shopping" xmlns:a="http://schemas.datacontract.org/2004/07/Trevoo.WS.Entities.Shopping" xmlns:b="http://schemas.datacontract.org/2004/07/Trevoo.WS.Entities.Air" xmlns:c="http://schemas.microsoft.com/2003/10/Serialization/Arrays" xmlns:bb="http://schemas.datacontract.org/2004/07/Trevoo.WS.Entities.Shopping.Views" exclude-result-prefixes="res a b c bb">
   <xsl:output method="xml" indent="yes"/>

   <xsl:key name="item" match="b:T_AirBookingItem" use="concat(generate-id(..) , '|', a:LocalPaxType)"/>

   <xsl:template match="/">
      <xsl:apply-templates select="//a:T_ShoppingFile"/>
   </xsl:template>

   <xsl:template match="a:T_ShoppingFile">
      <file number="{position()}">
         <xsl:apply-templates select="b:T_AirBookingItem[generate-id() = generate-id(key('item', concat(generate-id(..) , '|', a:LocalPaxType))[1])]"/>
      </file>
   </xsl:template>

   <xsl:template match="b:T_AirBookingItem">
      <result>
         <xsl:value-of select="concat(a:LocalPaxType, ' * ', count(key('item', concat(generate-id(..) , '|', a:LocalPaxType))), '&#13;')"/>
      </result>
   </xsl:template>
</xsl:stylesheet>

应用于XML时，输出以下内容

<file number="1">
   <result>ADT * 1</result>
   <result>CHD * 1</result>
   <result>INF * 1</result>
</file>
<file number="2">
   <result>ADT * 1</result>
</file>

显然，这会显示所有 a：T_ShoppingFile 和 a：LocalPaxType 的结果。如果您想限制为特定的 a：LocalPaxType ，您可以执行类似的操作（尽管您可能希望参数化该值，而不是硬编码 ADT

   <xsl:template match="a:T_ShoppingFile">
      <file number="{position()}">
         <xsl:value-of select="count(key('item', concat(generate-id() , '|', 'ADT')))" />
      </file>
   </xsl:template>

Group By XSLT 1.0，group of group

1 个答案: