Question

我需要使用非常适合正则表达式的XSLT 1.0执行查找和替换。不幸的是，这些在1.0中不可用，而且我也无法使用任何扩展库，例如EXSLT，因为我无法更改安全设置。

我正在使用的字符串如下：

19;#John Smith;#17;#Ben Reynolds;#1;#Terry Jackson

我需要用; #替换数字和,个字符。例如，上面将改为：

John Smith, Ben Reynolds, Terry Jackson

我知道需要递归字符串函数，可能使用substring和translate，但我不知道从哪里开始。

有没有人对如何解决这个问题有一些指导？以下是我的开始：

<xsl:template name="TrimMulti">
    <xsl:param name="FullString" />
    <xsl:variable name="NormalizedString">
        <xsl:value-of select="normalize-space($FullString)" />
    </xsl:variable>
    <xsl:variable name="Hash">#</xsl:variable>
    <xsl:choose>
        <xsl:when test="contains($NormalizedString, $Hash)">
            <!-- Do something and call TrimMulti -->
        </xsl:when>
    </xsl:choose>
</xsl:template>

Answer 1

我希望你没有过多地简化这个问题，因为这不应该是一个问题。

只要保持输入字符串的格式一致，就可以定义模板并以递归方式调用它。

例如，

<xsl:template name="TrimMulti">
  <xsl:param name="InputString"/>
  <xsl:variable name="RemainingString" 
    select="substring-after($InputString,';#')"/>
  <xsl:choose>
    <xsl:when test="contains($RemainingString,';#')">
      <xsl:value-of 
        select="substring-before($RemainingString,';#')"/>
      <xsl:text>, </xsl:text>
      <xsl:call-template name="TrimMulti">
        <xsl:with-param 
          name="InputString"
          select="substring-after($RemainingString,';#')"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="$RemainingString"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

我使用以下调用测试了此模板：

<xsl:template match="/">
  <xsl:call-template name="TrimMulti">
    <xsl:with-param name="InputString">19;#John Smith;#17;#Ben Reynolds;#1;#Terry Jackson</xsl:with-param>
  </xsl:call-template>
</xsl:template>

得到以下输出：

John Smith, Ben Reynolds, Terry Jackson

这似乎就是你所追求的目标。

如果您熟悉函数式编程，那么解释它的作用很容易解释。 InputString参数的格式始终为[number];#[name];#[rest of string]。 TrimMulti模板的每次调用都会从[number];#部分中删除并打印出[name]部分，然后递归地将剩余的表达式传递给自身。

基本情况是InputString的格式为[number];#[name]，在这种情况下，RemainingString变量不会包含;#。因为我们知道这是输入的结束，所以这次我们不输出逗号。

Answer 2

如果';'和'＃'字符在输入中无效，因为它们是分隔符，那么为什么翻译功能不起作用？它可能很难看（你必须在第二个参数中指定所有有效字符并在第三个参数中重复它们）但是它会更容易调试。

translate($InputString, ';#abcdefghijklmnopqrstuvABCDEFGHIJKLMNOPQRSTUZ0123456789,- ', ', abcdefghijklmnopqrstuvABCDEFGHIJKLMNOPQRSTUZ0123456789,- ')

XSLT 1.0中的“正则表达式”式替换

2 个答案: