Question

当您使用非英语（俄语）键盘布局时，是否有一种简单的方法可以使用Emacs键绑定？

每当启用国际布局时，所有按键都按字面解释，M-ф代替M-a。结果我无法使用命令。

如果Linux可以根据国际布局解释非前缀和移位前缀键，同时保留其余的英语，那也不错。

Answer 1

您可以输入

设置输入法（kudos转到 kindahero ）

M-x set-input-method RET cyrillic-yawerty RET

或

M-x set-input-method RET cyrillic-jcuken RET

要永久存储，请添加

(setq default-input-method "cyrillic-yawerty")

到〜/ .emacs config（并使用 C - \ 在键盘布局之间切换）。

Answer 2

这是一种使用OS语言的替代解决方案，基于syndikat的回答。

缺少一些关键翻译，但添加它们应该很容易。

;; USAGE:
;; Put in your .emacs:
;; 
;; (translate-keystrokes-ru->en)
;; (add-hook 'text-mode-hook
;;           (lambda () (literal-insert-mode 1)))
;; 
;; Only buffers with literal-insert-mode active will be sensitive to the
;; environment language. Prefixed keybindings will still be usable.

(defun translate-keystrokes-ru->en ()
  "Make emacs output english characters, regardless whether
the OS keyboard is english or russian"
  (flet ((make-key-stroke (prefix char)
           (eval `(kbd ,(if (and (string-match "^C-" prefix)
                                 (string-match "[A-Z]" (string char)))
                            (concat "S-" prefix (string (downcase char)))
                            (concat prefix (string char)))))))
    (let ((case-fold-search nil)
          (keys-pairs (mapcar* 'cons
                               "йцукенгшщзхъфывапролджэячсмитьбюЙЦУКЕНГШЩЗХЪФЫВАПРОЛДЖ\ЭЯЧСМИТЬБЮ№"
                               "qwertyuiop[]asdfghjkl;'zxcvbnm,.QWERTYUIOP{}ASDFGHJKL:\"ZXCVBNM<>#"))
          (prefixes '(""    "s-"    "M-"    "M-s-"
                      "C-"  "C-s-"  "C-M-"  "C-M-s-")))
      (mapc (lambda (prefix)
              (mapc (lambda (pair)
                      (define-key key-translation-map
                          (make-key-stroke prefix (car pair))
                        (make-key-stroke prefix (cdr pair))))
                    keys-pairs))
            prefixes))))

(defun literal-insert ()
  (interactive)
  (insert-char last-input-event 1))

(define-minor-mode literal-insert-mode
    "Make emacs output characters corresponging to the OS keyboard,
 ignoring the key-translation-map"
  :keymap (let ((new-map (make-sparse-keymap))
                (english-chars "qwertyuiop[]asdfghjkl;'zxcvbnm,.QWERTYUIOP{}ASDFGHJKL:\"ZXCVBNM<>#"))
            (mapc (lambda (char)
                    (define-key new-map (string char)
                      'literal-insert))
                  english-chars)
            new-map))

Answer 3

不确定，sabof在哪里得到了1500亿。我运行了这段代码（感谢Yuri Khan，取自EmacsWiki）：

(loop
 for from across "йцукенгшщзхъфывапролджэячсмитьбюЙЦУКЕНГШЩЗХЪФЫВАПРОЛДЖ\ЭЯЧСМИТЬБЮ№"
 for to   across "qwertyuiop[]asdfghjkl;'zxcvbnm,.QWERTYUIOP{}ASDFGHJKL:\"ZXCVBNM<>#"
 do
 (eval `(define-key key-translation-map (kbd ,(concat "C-" (string from))) (kbd ,(concat     "C-" (string to)))))
 (eval `(define-key key-translation-map (kbd ,(concat "M-" (string from))) (kbd ,(concat     "M-" (string to))))))

这只有128种组合。不幸的是，单字母组合如 C-x b 不起作用。我仍在努力寻找更好的解决方案。

Answer 4

我将以下代码片段用于西里尔文键盘，对我来说效果很好：

(defun reverse-input-method (input-method)
  "Build the reverse mapping of single letters from INPUT-METHOD."
  (interactive
   (list (read-input-method-name "Use input method (default current): ")))
  (if (and input-method (symbolp input-method))
      (setq input-method (symbol-name input-method)))
  (let ((current current-input-method)
        (modifiers '(nil (control) (meta) (control meta))))
    (when input-method
      (activate-input-method input-method))
    (when (and current-input-method quail-keyboard-layout)
      (dolist (map (cdr (quail-map)))
        (let* ((to (car map))
               (from (quail-get-translation
                      (cadr map) (char-to-string to) 1)))
          (when (and (characterp from) (characterp to))
            (dolist (mod modifiers)
              (define-key local-function-key-map
                (vector (append mod (list from)))
                (vector (append mod (list to)))))))))
    (when input-method
      (activate-input-method current))))

(reverse-input-method 'russian-computer)

除了：

我知道的唯一问题是，不是重新计算OrgTable公式在俄罗斯布局中工作，因为它映射到C-c- *和* change 它的位置。

source

Answer 5

如果你想继续在Emacs中使用俄语布局（而不是使用Emacs自己的输入法），我现在知道的唯一方法就是添加表格的绑定：

(define-key function-key-map [?\M-ф] [?\M-a])

这将告诉Emacs，如果没有绑定M-ф，它应该尝试查找M-a。可悲的是，你需要很多这些绑定。如果有人写了一个可以自动提供所有这些绑定的补丁/包，我很乐意将它包含在Emacs中。

Emacs，Linux和国际键盘布局

5 个答案: