Question

问题1：

我想将数组传递给函数。但是在函数中改变了传递的参数。它是按值调用的吗？

问题2：

#my ($name, $num, @array)= @_;   <=1 )
my $name = shift;                <=2 )
my $num = shift;
my @array = shift;

案例1和案例2有不同的输出。它为什么会发生？

#!/usr/bin/perl
use strict;

my @test1;
push @test1, ['a', 1];
push @test1, ['b', 1];
push @test1, ['c', 1];
push @test1, ['d', 1];
push @test1, ['e', 1];

for (my $i=0; $i< scalar(@test1); $i++) {
    print "out1: $test1[$i][0]  $test1[$i][1]\n";
}

test_func("test_func", 10, @test1);

sub test_func {
    #my ($name, $num, @array)= @_;   <=1)
    my $name = shift;                <=2)
    my $num = shift;
    my @array = shift;

    print "$name\n";
    print "$num\n";

    for (my $i=0; $i< scalar(@test1); $i++) {
        print "$array[$i][0]  $array[$i][1]\n";
    }

    for (my $i=0; $i< scalar(@test1); $i++) {
        if ($array[$i][0] eq 'a') {
            $array[$i][0] = 'z';
        }
    }
    for (my $i=0; $i< scalar(@test1); $i++) {
        print "change: $array[$i][0]  $array[$i][1]\n";
    }
}

for (my $i=0; $i< scalar(@test1); $i++) {
    print "out2: $test1[$i][0]  $test1[$i][1]\n";
}

＃

以下是测试输出。

out1: a  1
out1: b  1
out1: c  1
out1: d  1
out1: e  1
test_func
10
a  1
b  1
c  1
d  1
e  1
change: z  1
change: b  1
change: c  1
change: d  1
change: e  1
out2: z  1 <= Why did it change?
out2: b  1
out2: c  1
out2: d  1
out2: e  1

Answer 1

我想将数组传递给函数[...]有不同的输出。它为什么会出现？

您无法将数组传递给函数子。 Subs只能将标量列表作为参数。

test_func("test_func", 10, @test1);

与

相同

test_func("test_func", 10, $test1[0], $test1[1], $test1[2], $test1[3], $test1[4]);

当您执行

时，您正在test_func中创建一个新数组

my ($name, $num, @array) = @_;

shift返回@_的第一个元素，它必然是标量。 @_是一个数组，数组的元素是标量。等价物是

my $name  = shift(@_);
my $num   = shift(@_);
my @array = splice(@_);

要将数组传递给sub，通常会将引用传递给它。

test_func("test_func", 10, \@test1);

my ($name, $num, $array) = @_;

my $name  = shift;
my $num   = shift;
my $array = shift;

say "@$array";

但是在函数中更改了传递的参数。是按值调用吗？

Perl永远不会超值。它总是通过引用传递。如果更改@_的任何元素，它将更改调用者中的相应参数。

$ perl -E'sub f { $_[0] = "def"; }  my $x = "abc"; f($x); say $x;'
def

但这不是问题。您不会更改@_的任何元素。您正在做的是更改$test[0]和$array[0]引用的单个数组。

这就是你在做的事情：

my $ref1 = [ 'a', 1 ];  # aka $test1[0]
my $ref2 = $ref1;       # aka $array[0]
$ref2->[0] = 'z';       # Changes the single array (not $ref1 or $ref2).

这是

的缩写

my @anon = ( 'a', 1 );
my $ref1 = \@anon;      # aka $test1[0]
my $ref2 = $ref1;       # aka $array[0]
$ref2->[0] = 'z';       # Changes @anon (not $ref1 or $ref2).

Storable的dclone可用于制作数组的“深层副本”。

my $ref1 = [ 'a', 1 ];
my $ref2 = dclone($ref1);  # clones the reference, the array, 'a' and 1.
$ref1->[0] = 'y';          # Changes the original array
$ref2->[0] = 'z';          # Changes the new array

如何将数组传递给Perl中的函数？

1 个答案: