Question

我知道我在下面描述的并不是技术上的多播，但我对我想要做的事情缺乏更好的描述。

我目前有一个带有OnExecute的TIdTCPServer，它读取传入的消息，将响应消息生成到线程安全队列中，然后调用一个函数来逐步执行队列并将消息发送回客户端。这部分代码正常工作，允许客户端请求数据集。

当客户端更改服务器上的对象时，我希望所有客户端都收到此更改的通知。代码当前将通知消息添加到每个连接的每个队列。我的问题是OnExecute没有循环，所以在服务器从客户端收到消息之前，不会调用在队列上发送消息的调用。

有没有办法让OnExecute循环？或者为连接触发OnExecute的方法我知道我已将消息排队了吗？

我的过程TWinSocketSession对象具有对连接的引用，并包含传出消息Queue的代码。它还有一个名为SendMessages的过程，它遍历队列并调用Connection.Write。以下是我的OnExecute程序。

procedure TWinServerSession.IdTCPServer1Execute(AThread: TIdPeerThread);
  Var
    i:           Integer;
    strMessage:  String;
  begin
    //find the Socket Session for connection
    for i := 0 to m_usClientCount do
      begin
        if m_mWinSocketSession[i]<>Nil then
          if ( m_mWinSocketSession[i].Connection = Athread.Connection ) then break;
      end;

    //read the message
    strMessage := m_mWinSocketSession[i].Connection.ReadLn(#0,25,-1);

    //parse the message and populate the Queue with outgoing messages
    m_mWinSocketSession[i].ParseInString(strMessage);

    //send all of the outgoing messages
    m_mWinSocketSession[i].SendMessages;
  end;

Answer 1

是的，TIdTCPServer.OnExecute事件 IS 是一个循环事件。入站邮件到达时， NOT 会被触发。无论连接实际在做什么，它都会在连续的生命周期内以连续循环方式触发。它是事件处理程序根据需要实现阻塞行为的责任。您的代码正在调用ReadLn()并指定了25ms的超时，因此它不会阻止事件处理程序及时退出，因此它可以立即重新输入。如果阻止事件处理程序及时退出，那么代码中的其他地方就会出现死锁问题。

但我会建议以下更改：

procedure TWinServerSession.IdTCPServer1Connect(AThread: TIdPeerThread); 
var
  i: Integer;
begin 
  for i := 0 to m_usClientCount do  
  begin  
    if (m_mWinSocketSession[i] = nil) then
    begin
      m_mWinSocketSession[i] := TWinSocketSession.Create;
      m_mWinSocketSession[i].Connection := AThread.Connection;

      // for easier access in the other events...
      AThread.Data := m_mWinSocketSession[i];  

      Exit;
    end;
  end;

  // cannot start a new session
  AThread.Connection.Disconnect;
end; 

procedure TWinServerSession.IdTCPServer1Disconnect(AThread: TIdPeerThread); 
var
  session: TWinSocketSession;
  i: Integer;
begin 
  session := TWinSocketSession(AThread.Data);
  AThread.Data := nil;

  if session <> nil then
  begin      
    for i := 0 to m_usClientCount do  
    begin  
      if m_mWinSocketSession[i] = session then
      begin
        m_mWinSocketSession[i] := nil;
        Break;
      end;
    end;
    session.Free;
  end;
end; 

procedure TWinServerSession.IdTCPServer1Execute(AThread: TIdPeerThread); 
var 
  session: TWinSocketSession;
  strMessage:  String; 
begin 
  session := TWinSocketSession(AThread.Data);

  //read a message  
  strMessage := AThread.Connection.ReadLn(#0, 25, -1);  
  if not AThread.Connection.ReadLnTimedOut then
  begin
    //parse the message and populate the Queue with outgoing messages  
    session.ParseInString(strMessage);  
  end;

  //send all of the outgoing messages  
  session.SendMessages;  
end;

如果您可以完全消除m_mWinSocketSession列表并且只是在OnConnect事件中将新队列直接分配给Connection，那么这将更好。 OnDisconnect事件可以当客户端断开连接时释放队列。

procedure TWinServerSession.IdTCPServer1Connect(AThread: TIdPeerThread); 
begin
  AThread.Data := TWinSocketSession.Create;
  TWinSocketSession(AThread.Data).Connection := AThread.Connection;
end;

procedure TWinServerSession.IdTCPServer1Disconnect(AThread: TIdPeerThread); 
begin
  session := TWinSocketSession(AThread.Data);
  AThread.Data := nil;
  session.Free;
end;

使用TIdTCPServer进行多播（Indy 9 + Delphi 7）

1 个答案: