Question

我正在编写一个需要进行日志记录的简单Groovy应用程序。记录事物的实际属性取决于特定环境。例如，在开发时我只想登录到控制台，在测试和生产中我可能想写一个文件，在生产中我可能想发送最严重事件的电子邮件。

现在我正在做的事情是这样的：

import org.apache.log4j.Logger
import org.apache.log4j.PropertyConfigurator

class BaseClass {
    protected config

    static Logger logger = Logger.getLogger(BaseClient.class)

    def BaseClass(env) {
        def configFilePath = // whatever

        config = new JsonSlurper().parseText(configFile.text)[options.env]

        def logConfigFilePath = ['somelogdir', config.log_file].join(File.separator)
        PropertyConfigurator.configure(logConfigFilePath)
    }
}

然后我需要进行日志记录的所有类都继承自BaseClass。

通过这种方式，我可以为每个环境指定不同的文件名，然后从那里读取日志记录配置。但它似乎有很多样板，并迫使我使用可能不理想的层次结构。

另一方面，here我看到我可以获得一个带有简单注释的记录器。

有没有办法根据环境获得不同的记录器 - 可以在运行时设置？

Answer 1

在tim_yates的答案的基础上，使用groovy文件配置log4j。例如：

// log4j.groovy
log4j {
    rootLogger="DEBUG, A1"
    appender.A1 = "org.apache.log4j.ConsoleAppender"
    appender.'A1.layout' = "org.apache.log4j.PatternLayout"

    if (System.properties['env'] == 'prod') {
        appender.'A1.layout.ConversionPattern'="prod %-4r [%t] %-5p %c %x - %m%n"
   } else {
        appender.'A1.layout.ConversionPattern'="dev %-4r [%t] %-5p %c %x - %m%n"
   }
}

然后让你的脚本使用它：

@GrabConfig(systemClassLoader=true)
@Grab(group='log4j', module='log4j', version='1.2.17')

import groovy.util.logging.Log4j
import org.apache.log4j.PropertyConfigurator

@Log4j
class Test {
    def dosome() {
        log.info('Logging!')
    }

    static main( args ) {
        def config = new ConfigSlurper().parse(new File('log4j.groovy').toURL())
        PropertyConfigurator.configure(config.toProperties())

        new Test().dosome()
    }
}

最后，在环境中使用系统属性启动程序：

groovy -Denv=prod Test.groovy

Answer 2

您应该只需在类路径中放置一个log4j.properties文件。

鉴于此测试脚本：

@groovy.util.logging.Log4j
class Test {
  def dosome() {
    log.info( 'Logging!' )
  }

  static main( args ) {
    new Test().dosome()
  }
}

如果我从命令行运行它：

groovy -cp log4j-1.2.17.jar Test.groovy

它不会打印任何内容，因为默认情况下它未设置为记录INFO消息。

但是，如果我写一个log4j.properties文件（taken from the docs for log4j并更改为log）：

log4j.rootLogger=DEBUG, A1

log4j.appender.A1=org.apache.log4j.ConsoleAppender
log4j.appender.A1.layout=org.apache.log4j.PatternLayout

# Print the date in ISO 8601 format
log4j.appender.A1.layout.ConversionPattern=%d [%t] %-5p %c - %m%n

然后在类路径中使用此属性文件再次运行它：

groovy -cp log4j.properties:log4j-1.2.17.jar Test.groovy

我们得到：

2012-07-16 16:08:47,524 [main] INFO  Test - Logging!

Groovy - 根据环境配置日志记录属性

2 个答案: