Question

我发布在IE 9 not accepting SendKeys to download a file，但这个问题与我收到的答案是分开的，足以证明另一个问题。我的问题是我无法让IE 9接受任何SendKeys。我尝试了 Page Down ， Tab ，所有 F＃键，但都没有。

以下是我正在使用的代码：

Dim ie As Object

'This creates the IE object
Sub initializeIE()
   'call this subprocedure to start internet explorer up
   Set ie = CreateObject("internetexplorer.application")
   pos = 1
End Sub

'Initialize the class object
Private Sub Class_Initialize()
   initializeIE
End Sub

Function followLinkByText(thetext As String) As Boolean
  'clicks the first link that has the specified text
  Dim alink As Variant

  'Loops through every anchor in html document until specified text is found
  ' then clicks the link
  For Each alink In ie.document.Links
     If alink.innerHTML = thetext Then
          alink.Click
          'waitForLoad
          Application.Wait Now + TimeValue("00:00:01")
          Application.SendKeys "{PGDN}", True
          Application.SendKeys "{PGUP}", True
          'I've also tried calling it without Application before it
          SendKeys "{F1}", True
          SendKeys "{F2}", True
          'Etc... Each of these not being received by IE 9

          followLinkByText = True
          Exit Function
      End If
  Next

End Function

我完全失去了，因为似乎大多数论坛或教程都没有为IE 9做任何不同的事情.IE对象是在类模块中创建的，并在Class_Initialize sub中初始化。我不确定这是否有帮助，但我真的不知道为什么这不起作用，如何向IE发送密钥的任何帮助将不胜感激。

Answer 1

这实际上是my answer到this question的副本，但它仍可能适用。

尝试SendKeys时，IE窗口是否处于活动状态？如果没有，这可以解释它不起作用。

激活你的窗口：

在模块的开头，输入以下代码：

Public Declare Function SetForegroundWindow Lib "user32" (ByVal HWND As Long) As Long

这将允许您访问Windows内置的SetForegroundWindow功能。

在代码中，在与IE对象交互时，记录该窗口的HWND，如下所示：

Dim HWNDSrc As Long
HWNDSrc = ie.HWND

然后在您加载页面后，使用此选项继续，然后发送您的关键操作：

SetForegroundWindow HWNDSrc

但是，这可能没有必要，具体取决于您与IE的交互方式。换句话说，如果您不需要查看/触摸窗口（使用SendKeys），您仍然可以使用代码中的对象进行交互。

现在，我看到您在单击后使用Application.Wait，但这并不能保证IE页面已加载。这个功能应该有帮助。

 Public Sub WaitForIE(myIEwindow As InternetExplorer, HWND As Long, WaitTime As Integer)

    ' Add pauses/waits so that window action can actually
    ' begin AND finish before trying to read from myIEWindow.

    ' myIEWindow is the IE object currently in use
    ' HWND is the HWND for myIEWindow
    ' The above two variables are both used for redundancy/failsafe purposes.
    ' WaitTime is the amount of time (in seconds) to wait at each step below. 
    ' This is variablized because some pages are known to take longer than 
    ' others to load, and some pages with frames may be partially loaded,
    ' which can incorrectly return an READYSTATE_COMPLETE status, etc.

    Dim OpenIETitle As SHDocVw.InternetExplorer

    Application.Wait DateAdd("s", WaitTime, Now())

    Do Until myIEwindow.ReadyState = READYSTATE_COMPLETE
        ' Wait until IE is done loading page and/or user actions are done.
    Loop

    Application.Wait DateAdd("s", WaitTime, Now())

    While myIEwindow.Busy
        DoEvents  ' Wait until IE is done loading page and/or user actions are done.
    Wend

    On Error Resume Next
    ' Make sure our window still exists and was not closed for some reason...
    For Each OpenIETitle In objShellWindows
        If OpenIETitle.HWND = HWND Then
            If Err.Number = 0 Then
                Set myIEwindow = OpenIETitle
                Exit For
            Else
                Err.Clear
            End If
        End If
    Next OpenIETitle
    On Error GoTo 0

End Sub

冒着啰嗦的风险，我已经用这些建议更新了你的代码......

' Added by Gaffi
Public Declare Function SetForegroundWindow Lib "user32" (ByVal HWND As Long) As Long
Dim HWNDSrc As Long

Dim ie As Object


'This creates the IE object
Sub initializeIE()
   'call this subprocedure to start internet explorer up
   Set ie = CreateObject("internetexplorer.application")

' Added by Gaffi
   HWNDSrc = ie.HWND

   pos = 1
End Sub

'Initialize the class object
Private Sub Class_Initialize()
   initializeIE
End Sub

Function followLinkByText(thetext As String) As Boolean
  'clicks the first link that has the specified text
  Dim alink As Variant

  'Loops through every anchor in html document until specified text is found
  ' then clicks the link
  For Each alink In ie.document.Links
     If alink.innerHTML = thetext Then
          alink.Click
          'waitForLoad

' Added by Gaffi
          WaitForIE ie, HWNDSrc, 1
          SetForegroundWindow HWNDSrc

          'Application.Wait Now + TimeValue("00:00:01")
          Application.SendKeys "{PGDN}", True
          Application.SendKeys "{PGUP}", True
          'I've also tried calling it without Application before it
          SendKeys "{F1}", True
          SendKeys "{F2}", True
          'Etc... Each of these not being received by IE 9

          followLinkByText = True
          Exit Function
      End If
  Next

End Function

IE 9不接受SendKeys

1 个答案: