Question

我有3个表作为测试1，测试2和测试3。

测试1，是销售表。销售详细信息记录在哪里。它将生成销售ID。

测试2，是用于记录在此特定销售ID中销售的所有产品的表。我使用openxml来插入这些细节。请在下面找到用于更新测试1和测试2表的存储过程。

CREATE PROCEDURE UpdateSales
(
@SalesID int out,
@SalesDate Date,
@XmlString text
) 
AS
BEGIN
SET NOCOUNT ON
BEGIN TRANSACTION
BEGIN TRY

INSERT INTO Test1 (SalesDate) VALUES (@SalesDate);
SET @SalesID = SCOPE_IDENTITY();

DECLARE @XMLDocPointer int;
EXEC sp_xml_preparedocument @XMLDocPointer OUTPUT, @XmlString;

INSERT INTO Test2 (SalesID, ProductId, ProductName, qty)
    SELECT @SalesID, productId, productName, qty
    FROM OPENXML(@XmlDocPointer, '/Root/Products', 2)
    WITH (productId int,
        productName varchar(100),
        qty int);

EXEC sp_xml_removedocument @XMLDocPointer 

COMMIT TRANSACTION
END TRY

BEGIN CATCH
ROLLBACK TRANSACTION
END CATCH

END
GO

表3是产品表。根据销售的产品，需要更新数量。我在插入后在Test 2表上使用了一个触发器。请在下面找到使用的触发器。

CREATE TRIGGER updateQty ON Test2
AFTER INSERT
AS
DECLARE @productID int;
DECLARE @qty int;

SELECT @productID = ProductId FROM INSERTED;
SELECT @qty = qty FROM INSERTED;

DECLARE @currentQty int;
SELECT @currentQty = qty FROM Test3 WHERE productID = @productID;
UPDATE Test3 SET qty = @currentQty - @qty WHERE productID = @productID;
GO

当我尝试执行存储过程以将记录插入到Test 1和Test 2表时，因为我有一个触发器需要更新Test 3表。请在下面找到我使用的执行语句，只在测试3表中更新产品ID 1。请帮我解决这个问题。 tanx提前。

声明已执行。

EXEC UpdateSales 
'1' , '08/08/2012' , 
'
<Root>
<Products>
<productId>1</productId>
<productName>Product 1</productName>
<qty>1</qty>
</Products>
<Products>
<productId>2</productId>
<productName>Product 2</productName>
<qty>2</qty>
</Products>
<Products>
<productId>3</productId>
<productName>Product 3</productName>
<qty>3</qty>
</Products>
</Root> 
'
GO

Answer 1

您的触发器是单行触发器。它需要对插入的表中的所有记录起作用。

未经测试，但您的更新触发器shouuld看起来像这样更新所有受影响的行：

CREATE TRIGGER updateQty ON Test2 
AFTER INSERT 
AS 

UPDATE Test3 
  SET qty = qty - i.qty
from test3 t
join inserted i on i.productid = t.productid

GO

触发器不会更新受影响的所有行

1 个答案: