Question

<page>
  <tab dim="70"></tab>
  <tab dim="40"></tab>
  <tab dim="30"></tab>
  <tab dim="30"></tab>
  <tab dim="30"></tab>
  <tab dim="70"></tab>
</page>

如何获取tab的dim属性的值，并使用xslt.means取出不同的值，它将打印30,40,70

Answer 1

要选择不同的属性值，可以使用此XPath：

/page/tab[not(@dim=preceding-sibling::tab/@dim)]/@dim

可能的XSLT模板是

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text" />
    <xsl:template match="/">
        <xsl:for-each select="/page/tab[not(@dim=preceding-sibling::tab/@dim)]/@dim">
            <xsl:sort select="." data-type="number"/>
            <xsl:value-of select="concat(., substring(',', 2 - (position() != last())))"/>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

要transform the source document with the stylesheet in PHP，您可以使用：

$xml = new DOMDocument;
$xml->load('collection.xml');
$xsl = new DOMDocument;
$xsl->load('collection.xsl');
$proc = new XSLTProcessor;
$proc->importStyleSheet($xsl);
echo $proc->transformToXML($xml);

这将在输出中给出30,40,70。

只需执行以下操作即可在没有XSLT的情况下实现相同目的：

$page = simplexml_load_file('NewFile.xml');
$dims = $page->xpath('/page/tab[not(@dim=preceding-sibling::tab/@dim)]/@dim');
$dims = array_map('strval', $dims);
sort($dims);
echo implode(',', $dims);

另见

Answer 2

使用preceding-sibling::someName进行分组的速度非常慢（O（N ^ 2） - 二次方）并且在大型节点集上使用时可能过于禁止。

这是一个简单而有效的Muenchian grouping解决方案：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>
 <xsl:key name="kTabByDim" match="tab" use="@dim"/>

 <xsl:template match="/*">
  <xsl:apply-templates select=
   "tab[generate-id()=generate-id(key('kTabByDim',@dim)[1])]">
    <xsl:sort select="@dim" data-type="number"/>
  </xsl:apply-templates>
 </xsl:template>
 <xsl:template match="tab">
   <xsl:if test="position() >1">,</xsl:if>
   <xsl:value-of select="@dim"/>
 </xsl:template>
</xsl:stylesheet>

在提供的XML文档上应用此转换时：

<page>
  <tab dim="70"></tab>
  <tab dim="40"></tab>
  <tab dim="30"></tab>
  <tab dim="30"></tab>
  <tab dim="30"></tab>
  <tab dim="70"></tab>
</page>

产生了想要的正确结果：

30,40,70

使用xslt获取属性节点并打印不同的值

2 个答案: