Question

我正在尝试了解如何限制 Windows批处理文件中的程序执行时间。是否有类似Unix timeout命令的东西？请指教。

Answer 1

要限制程序运行的时间，您可以执行类似这样的操作

start yourprogram.exe
timeout /t 10
taskkill /im yourprogram.exe /f

开始yourprogram.exe，等待10秒，然后杀死程序。

Answer 2

我刚刚安装了Cygwin并使用了发行版中的unix-style timeout命令。

Answer 3

我认为没有超时命令。但是，您可以在后台开始执行任务并使用ping（使用ping）超时，然后终止任务。

Answer 4

此代码等待60秒，然后检查％ProgramName％是否正在运行。

要增加此时间，请更改WaitForMinutes的值。

要缩短检查间隔，请将WaitForSeconds设置为您希望等待的秒数。

@echo off
set ProgramName=calc.exe
set EndInHours=2

:: How Many Minutes in between each check to see if %ProgramName% is Running
:: To change it to seconds, just set %WaitForSeconds% Manually
set WaitForMinutes=1
set /a WaitForSeconds=%WaitForMinutes%*60

:: How many times to loop
set /a MaxLoop=(%EndInHours%*60*60) / (%WaitForMinutes%*60)

REM Use a VBScript popup window asking to terminate %ProgramName%
echo set WshShell = WScript.CreateObject("WScript.Shell") > %tmp%\tmp.vbs
echo Wscript.Quit (WshShell.Popup( "Click 'OK' to terminate %ProgramName%." ,10 ,"Terminate %ProgramName%", 0)) >> %tmp%\tmp.vbs

start %ProgramName%
set running=True
:: Give time for %ProgramName% to launch.
timeout /t 5 /nobreak > nul
setlocal enabledelayedexpansion
for /l %%x in (1,1,%MaxLoop%) do (
  if "!running!"=="True" for /l %%y in (1,1,%WaitForMinutes%) do (
    if "!running!"=="True" (
      set running=False
      REM call Pop-Up
      cscript /nologo %tmp%\tmp.vbs
      if !errorlevel!==-1 (
        for /f "skip=3" %%x in ('tasklist /fi "IMAGENAME EQ %ProgramName%"') do set running=True
      ) else (
        taskkill /im %ProgramName%
      )
    )
  )
)
if exist %tmp%\tmp.vbs del %tmp%\tmp.vbs

此代码使用VBScript制作弹出框。点击OK将导致％{ProgramName％}被taskkill杀死。

如果您不想使用弹出窗口，可以通过移除timeout来使用...

REM Use a VBScript popup window asking to terminate %ProgramName%
echo set WshShell = WScript.CreateObject("WScript.Shell") > %tmp%\tmp.vbs
echo Wscript.Quit (WshShell.Popup( "Click 'OK' to terminate %ProgramName%." ,10 ,"Terminate %ProgramName%", 0)) >> %tmp%\tmp.vbs

...并替换此......

      REM call Pop-Up
      cscript /nologo %tmp%\tmp.vbs
      if !errorlevel!==-1 (

......用这个：

      REM Use CTRL+C to kill %ProgramName%
      timeout /t %WaitForSeconds% /nobreak
      if !errorlevel!==0 (

使用/nobreak是必要的，因为timeout无法区分按键或超时。这将允许您通过按 CTRL + C来终止％ProgramName％，但这会导致批处理文件在您执行时询问Terminate batch job (Y/N)?。邋/乱/讨厌的恕我直言。

您可以使用CHOICE替换上面提到的代码：

      REM Using choice, but choice can get stuck with a wrong keystroke
      Echo [K]ill %ProgramName% or [S]imulate %WaitForSeconds% Seconds
      Choice /n /c sk /t %WaitForSeconds% /d s
      if !errorlevel!==1 (

但是选择会给表带来一系列限制。首先，如果一个不在其中的键（在这种情况下为s和k）被按下，它将停止它的倒计时，基本上锁定直到做出正确的选择。其次， SPACEBAR 不能选择。

Windows批处理：用于`timeout`命令的模拟

4 个答案: