Question

如何使用单个命令禁用Oracle中的所有表约束？这可以是单个表，表列表，也可以是所有表。

Answer 1

最好避免写出临时假脱机文件。使用PL / SQL块。您可以从SQL * Plus运行它或将此内容放入包或过程中。与USER_TABLES的连接是为了避免视图约束。

您不太可能想要禁用所有约束（包括NOT NULL，主键等）。您应该考虑将constraint_type放在WHERE子句中。

BEGIN
  FOR c IN
  (SELECT c.owner, c.table_name, c.constraint_name
   FROM user_constraints c, user_tables t
   WHERE c.table_name = t.table_name
   AND c.status = 'ENABLED'
   AND NOT (t.iot_type IS NOT NULL AND c.constraint_type = 'P')
   ORDER BY c.constraint_type DESC)
  LOOP
    dbms_utility.exec_ddl_statement('alter table "' || c.owner || '"."' || c.table_name || '" disable constraint ' || c.constraint_name);
  END LOOP;
END;
/

再次启用约束有点过时 - 您需要先启用主键约束，然后才能在外键约束中引用它们。这可以使用constraint_type上的ORDER BY来完成。 'P'=主键，'R'=外键。

BEGIN
  FOR c IN
  (SELECT c.owner, c.table_name, c.constraint_name
   FROM user_constraints c, user_tables t
   WHERE c.table_name = t.table_name
   AND c.status = 'DISABLED'
   ORDER BY c.constraint_type)
  LOOP
    dbms_utility.exec_ddl_statement('alter table "' || c.owner || '"."' || c.table_name || '" enable constraint ' || c.constraint_name);
  END LOOP;
END;
/

Answer 2

计算约束之间的依赖关系：

SET Serveroutput ON
BEGIN
    FOR c IN
    (SELECT c.owner,c.table_name,c.constraint_name
    FROM user_constraints c,user_tables t
    WHERE c.table_name=t.table_name
    AND c.status='ENABLED'
    ORDER BY c.constraint_type DESC,c.last_change DESC
    )
    LOOP
        FOR D IN
        (SELECT P.Table_Name Parent_Table,C1.Table_Name Child_Table,C1.Owner,P.Constraint_Name Parent_Constraint,
            c1.constraint_name Child_Constraint
        FROM user_constraints p
        JOIN user_constraints c1 ON(p.constraint_name=c1.r_constraint_name)
        WHERE(p.constraint_type='P'
        OR p.constraint_type='U')
        AND c1.constraint_type='R'
        AND p.table_name=UPPER(c.table_name)
        )
        LOOP
            dbms_output.put_line('. Disable the constraint ' || d.Child_Constraint ||' (on table '||d.owner || '.' ||
            d.Child_Table || ')') ;
            dbms_utility.exec_ddl_statement('alter table ' || d.owner || '.' ||d.Child_Table || ' disable constraint ' ||
            d.Child_Constraint) ;
        END LOOP;
    END LOOP;
END;
/

Answer 3

这不是一个单一的命令，但这是我如何做到的。以下脚本已设计为在SQL * Plus中运行。请注意，我故意将其编写为仅在当前架构中工作。

set heading off

spool drop_constraints.out

select
    'alter table ' || 
    owner || '.' || 
    table_name || 
    ' disable constraint ' || -- or 'drop' if you want to permanently remove
    constraint_name || ';'
from
    user_constraints;

spool off

set heading on

@drop_constraints.out

要限制删除的内容，请在select语句中添加where子句： -

对constraint_type进行过滤以仅删除特定类型的约束
对table_name进行过滤，仅对一个或几个表执行此操作。

要运行多于当前架构，请修改select语句以从all_constraints而不是user_constraints中进行选择。

注意 - 由于某种原因，我不能让下划线在前一段中不像斜体那样表现。如果有人知道如何修复它，请随时编辑此答案。

Answer 4

使用以下光标禁用所有约束..并更改查询以启用约束...

DECLARE

cursor r1 is select * from user_constraints;
cursor r2 is select * from user_tables;

BEGIN
  FOR c1 IN r1
  loop
    for c2 in r2
    loop
       if c1.table_name = c2.table_name and c1.status = 'ENABLED' THEN
        dbms_utility.exec_ddl_statement('alter table ' || c1.owner || '.' || c1.table_name || ' disable constraint ' || c1.constraint_name);
       end if;
    end loop;
  END LOOP;
END;
/

Answer 5

这可以简单地基于DBA / ALL / USER_CONSTRAINTS系统视图在PL / SQL中编写脚本，但是各种细节并不像听起来那么简单。你必须要小心它的完成顺序，你还必须考虑到唯一索引的存在。

顺序很重要，因为你不能删除外键引用的唯一键或主键，并且在其他模式中的表中可能有外键引用你自己的主键，所以除非你有ALTER ANY TABLE特权然后你不能放弃那些PK和英国。此外，您不能将唯一索引切换为非唯一索引，因此您必须删除它才能删除约束（因此，将唯一约束实现为非“非”支持的“实际”约束几乎总是更好。 - 独特的指数）。

Answer 6

看起来你不能用一个命令做到这一点，但here'是我能找到的最接近它的东西。

Answer 7

在“禁用”脚本中，order by子句应为：

ORDER BY c.constraint_type DESC, c.last_change DESC

此子句的目标是以正确的顺序禁用约束。

Answer 8

SELECT 'ALTER TABLE '||substr(c.table_name,1,35)|| 
' DISABLE CONSTRAINT '||constraint_name||' ;' 
FROM user_constraints c, user_tables u 
WHERE c.table_name = u.table_name;

此语句返回关闭所有约束的命令，包括主键，外键和其他约束。

Answer 9

这是禁用约束的另一种方式（它来自https://asktom.oracle.com/pls/asktom/f?p=100:11:2402577774283132::::P11_QUESTION_ID:399218963817）

WITH qry0 AS
       (SELECT    'ALTER TABLE '
               || child_tname
               || ' DISABLE CONSTRAINT '
               || child_cons_name
                 disable_fk
              ,   'ALTER TABLE '
               || parent_tname
               || ' DISABLE CONSTRAINT '
               || parent.parent_cons_name
                 disable_pk
          FROM (SELECT a.table_name child_tname
                      ,a.constraint_name child_cons_name
                      ,b.r_constraint_name parent_cons_name
                      ,LISTAGG ( column_name, ',') WITHIN GROUP (ORDER BY position) child_columns
                  FROM user_cons_columns a
                      ,user_constraints b
                 WHERE a.constraint_name = b.constraint_name AND b.constraint_type = 'R'
                GROUP BY a.table_name, a.constraint_name
                        ,b.r_constraint_name) child
              ,(SELECT a.constraint_name parent_cons_name
                      ,a.table_name parent_tname
                      ,LISTAGG ( column_name, ',') WITHIN GROUP (ORDER BY position) parent_columns
                  FROM user_cons_columns a
                      ,user_constraints b
                 WHERE a.constraint_name = b.constraint_name AND b.constraint_type IN ('P', 'U')
                GROUP BY a.table_name, a.constraint_name) parent
         WHERE child.parent_cons_name = parent.parent_cons_name
           AND (parent.parent_tname LIKE 'V2_%' OR child.child_tname LIKE 'V2_%'))
SELECT DISTINCT disable_pk
  FROM qry0
UNION
SELECT DISTINCT disable_fk
  FROM qry0;

就像一个魅力

Answer 10

带有用于循环的光标（用户='TRANEE'，表='D'）

declare
    constr all_constraints.constraint_name%TYPE;
begin
    for constr in
        (select constraint_name from all_constraints
        where table_name = 'D'
        and owner = 'TRANEE')
    loop
        execute immediate 'alter table D disable constraint '||constr.constraint_name;
    end loop;
end;
/

（如果将禁用更改为启用，则可以使所有约束都启用）

Answer 11

您可以执行以下查询返回的所有命令：

选择'ALTER TABLE'|| substr（c.table_name，1,35）|| 'DISABLE CONSTRAINT'|| constraint_name ||' ;' 来自user_constraints c --where c.table_name ='TABLE_NAME';

禁用Oracle中的所有表约束

11 个答案: