有什么方法可以做到这一点?
for (int i = 0 ; i < 1000 ; i++)
for (int j = 0 ; j < 1000 ; j++)
ret = foo(i , j ) #I need the return value.
更多背景: 我正在解决euler problem 27,我得到了:
value a b =
let l = length $ takeWhile (isPrime) $ map (\n->n^2 + a * n + b) [0..]
in (l, a ,b)
下一步是通过循环遍历所有可能的a和b来获取元组列表,然后执行以下处理:
foldl (\(max,v) (n,a,b)-> if n > max then (n , a * b) else (max ,v) ) (0,0) tuple_list
但我不知道如何循环两个变量..谢谢。
答案 0 :(得分:24)
使用嵌套列表推导。这里'foo'是'(,)'':
[ (i,j) | i <- [0 .. 999], j <- [0 .. 999] ]
或布置以使嵌套更清晰:
[ foo i j
| i <- [0 .. 999]
, j <- [0 .. 999]
]
答案 1 :(得分:14)
除了dons的回答,你可以使用list monad:
do
i <- [0 .. 999]
j <- [0 .. 999]
return (foo i j)
答案 2 :(得分:8)
你也可以使用Control.Applicative
很好地完成这项工作module Main where
import Control.Applicative
main :: IO ()
main = mapM_ putStrLn (foo <$> [0..3] <*> [0..3])
foo :: Int -> Int -> String
foo a b = "foo " ++ show a ++ " " ++ show b
示例运行:
C:\programming>ghc --make Main.hs
[1 of 1] Compiling Main ( Main.hs, Main.o )
Linking Main.exe ...
C:\programming>main
foo 0 0
foo 0 1
foo 0 2
foo 0 3
foo 1 0
foo 1 1
foo 1 2
foo 1 3
foo 2 0
foo 2 1
foo 2 2
foo 2 3
foo 3 0
foo 3 1
foo 3 2
foo 3 3