Question

我有一个树语法，部分语法如下所示

transitions
    :'transitions' '=' INT ('(' INT ',' INT ')') + ';' -> ^(TRANSITIONS INT INT INT*)
    ;

，这是树解析器语法的相应部分，

transitions
    :^(TRANSITIONS INT INT INT*)
    {System.out.println("");}
    ;

我使用了+重写规则，这基本上是重复。在上面的语法中，用户输入的最小值为3个整数值一个可能的输入，

  transitions 1 (5,0)

第二个可能的输入

transitions 2 (5,0) (5,1)

第三种可能的输入

transitions 3 (5,0) (5,1) (5,2)

等等。
第一个整数确定将有多少对整数。问题是如何在我的解析器语法中访问这些整数输入，我怎么可能在上面的println语句中打印这些？

请参阅我的问题ANTLR java test file can't create object of tree grammar，了解我所写的完整语法。

Answer 1

我建议你保留＆＃34;对＆＃34;数字在一个单独的规则中：

解析器语法

transitions
 : 'transitions' '=' INT pair+ ';' -> ^(TRANSITIONS INT pair+)
 ;

pair
 : '(' INT ',' INT ')' -> ^(PAIR INT INT)
 ;

树语法

transitions
 : ^(TRANSITIONS INT pair+) {System.out.println("transitions.INT=" + $INT.text);}
 ;

pair
 : ^(PAIR a=INT b=INT) {System.out.println("pair=" + $a.text + ", " + $b.text);}
 ;

修改

快速演示：

grammar T;

options {
  output=AST;
  ASTLabelType=CommonTree;
}

tokens {
  TRANSITIONS;
  PAIR;
}

parse
 : transitions EOF!
   {
     CommonTree root = $transitions.tree;

     int count = root.getChildCount();

     Tree child1 = root.getChild(0);
     Tree child2 = root.getChild(1);
     Tree child3 = root.getChild(2);
     Tree child4 = root.getChild(3);

     System.out.println("root=" + root.getToken().getText() + " has " + count + " child nodes:");
     System.out.println(" - child1=" + child1.toStringTree());
     System.out.println(" - child2=" + child2.toStringTree());
     System.out.println(" - child3=" + child3.toStringTree());
     System.out.println(" - child4=" + child3.toStringTree());

     String secondValueFromLastPair = child4.getChild(1).getText();
     System.out.println("\nsecondValueFromLastPair=" + secondValueFromLastPair);
   }
 ;

transitions
 : 'transitions' '=' INT pair+ ';' -> ^(TRANSITIONS INT pair+)
 ;

pair
 : '(' INT ',' INT ')' -> ^(PAIR INT INT)
 ;

INT   : '0'..'9'+;
SPACE : ' ' {skip();};

如果你现在解析输入"transitions = 3(5,0) (5,1) (5,2);"，你会看到以下内容被打印到控制台：

root=TRANSITIONS has 4 child nodes:
 - child1=3
 - child2=(PAIR 5 0)
 - child3=(PAIR 5 1)
 - child4=(PAIR 5 1)

secondValueFromLastPair=2

ANTLR树解析器语法重写规则*

1 个答案:

解析器语法

树语法

修改