Question

我遇到了一些XSLT转换问题。在我的XML数据中有一些像这样的坐标元素：

XML：

[...]
<polygon some="attributes">
  <coordinates>
    <point>(8.234/9.435)</point>
    <point>(2.456/5.678)</point>
    [...]
  </coordinates>
</polygon>
[...]

等等。值表示x和y坐标（x / y）。现在我必须从特定的坐标集中得到x OR y的最大值或最小值。

我们在c ++代码中使用msxml，因此我不能将mSLT 2.0或XPath 2.0用于min（）和max（）函数。

格式（x / y）是静态的，我也不能改变它，因为它是程序的输出。

我尝试在XSLT中这样做：

XSLT：

<xsl:template name="getMinOf"> <!--this one is getting nodeset, min/max, x/y params-->
  <xsl:for-each select="$nodeSet"> <!--in this case "//polygon/coordinates/point"-->
    *<xsl:choose>
      <xsl:when test="$MinOrMax = 'min' ">
        <xsl:choose>
          <xsl:when test="$XorY = 'x'">*
        <xsl:sort select="substring-before(substring-after(.,'('),'/')" data-type="number" order="ascending"/> <!--Here is my problem-->
              <xsl:if test="position() = 1">
                <xsl:value-of select="." /><!--  return xMin -->
              </xsl:if>
          </xsl:when>
      [...]
</xsl:template>

select =“ substring-before（substring-after（。，'（'），'/'）”应该得到（和/，x坐标）之间的部分。如果我做了

<!--this one does return the x value.-->
<xsl:value-of select="substring-before(substring-after(.,'('),'/')"/>

所以...我希望你能理解我的问题，并能帮助我。我不知道如何进一步发展。感谢。

编辑：忘记了所需的输出。它应该是这样的：

<polygon>
  <xMin>2.456</xMin>
  <xMax>8.234</xMax>
  <yMin>5.678</yMin>
  <yMax>9.435</yMax>
</polygon>

Answer 1

虽然问题中没有提及，但我猜您的问题是您收到的消息是“关键字xsl：sort可能不会在这里使用。”，这是因为您的 xsl：sort 是嵌套在 xsl：when 时，它应该直接位于 xsl：for-each

之下

有效地，您正在尝试根据您的参数进行条件排序。一个条件是是对x坐标还是y坐标进行排序，另一个是对升序还是降序进行排序。

对于排序，您可以定义一个变量，该变量将保持“升序”或“降序”，然后按顺序排序：

  <xsl:variable name="order">
     <xsl:choose>
        <xsl:when test="$MinOrMax='max'">descending</xsl:when>
        <xsl:otherwise>ascending</xsl:otherwise>
     </xsl:choose>
  </xsl:variable>
  <xsl:for-each select="coordinates/point">
     <xsl:sort select="substring-before(substring-after(.,'('),'/')" data-type="number" order="{$order}"/>

下一个问题是如何根据您的参数选择'x'或'y'坐标。一种方法是使用 xsl：choose 在排序方法之间进行选择

  <xsl:choose>
     <xsl:when test="$XorY='x'">
        <xsl:for-each select="coordinates/point">
           <xsl:sort select="substring-before(substring-after(.,'('),'/')" data-type="number" order="{$order}"/>
           <xsl:if test="position() = 1">
              <xsl:value-of select="substring-before(substring-after(.,'('),'/')"/>
           </xsl:if>
        </xsl:for-each>         
     </xsl:when>
     <xsl:otherwise>
        <xsl:for-each select="coordinates/point">
           <xsl:sort select="substring-before(substring-after(.,'/'),')')" data-type="number" order="{$order}"/>
           <xsl:if test="position() = 1">
              <xsl:value-of select="substring-before(substring-after(.,'/'),')')"/>
           </xsl:if>
        </xsl:for-each>         
     </xsl:otherwise>
  </xsl:choose>

但是，有一种方法可以避免这种潜在的代码重复，并且只有一个 xsl：for-each 。试试这个排序

     <xsl:sort select="concat(
          substring(substring-before(substring-after(.,'('),'/'), 1, 100 * ($XorY = 'x')), 
          substring(substring-before(substring-after(.,'/'),')'), 1, 100 * ($XorY = 'y')))" 
       data-type="number" order="{$order}"/>

这利用了($XorY = 'x')将在表达式中评估为0或1的事实。为了更好地理解它，它实际上是对这两个表达式的连接：

substring(<x co-ordinate>, 1, 100 * <0 or 1>)
substring(<y co-ordinate>, 1, 100 * <0 or 1>)

当$ XorY ='x'时返回1，所以第一个子串（x坐标）返回一个完整的字符串，但第二个子串返回一个空字符串。当$ XorY ='y'时，相反的情况为真，并返回第二个子串（y坐标）。

试试这个XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>

   <xsl:template match="polygon">
      <polygon>
         <xMin>
            <xsl:call-template name="getMinOf">
               <xsl:with-param name="MinOrMax" select="'min'" />
               <xsl:with-param name="XorY" select="'x'" />
            </xsl:call-template>   
         </xMin>
         <xMax>
            <xsl:call-template name="getMinOf">
               <xsl:with-param name="MinOrMax" select="'max'" />
               <xsl:with-param name="XorY" select="'x'" />
            </xsl:call-template>   
         </xMax>
         <yMin>
            <xsl:call-template name="getMinOf">
               <xsl:with-param name="MinOrMax" select="'min'" />
               <xsl:with-param name="XorY" select="'y'" />
            </xsl:call-template>   
         </yMin>         
         <yMax>
            <xsl:call-template name="getMinOf">
               <xsl:with-param name="MinOrMax" select="'max'" />
               <xsl:with-param name="XorY" select="'y'" />
            </xsl:call-template>   
         </yMax>
      </polygon>
   </xsl:template>

   <xsl:template name="getMinOf">
      <xsl:param name="MinOrMax"/>
      <xsl:param name="XorY"/>
      <xsl:variable name="order">
         <xsl:choose>
            <xsl:when test="$MinOrMax='max'">descending</xsl:when>
            <xsl:otherwise>ascending</xsl:otherwise>
         </xsl:choose>
      </xsl:variable>
      <xsl:for-each select="coordinates/point">
         <xsl:sort select="concat(substring(substring-before(substring-after(.,'('),'/'), 1, 100 * ($XorY = 'x')), substring(substring-before(substring-after(.,'/'),')'), 1, 100 * ($XorY = 'y')))" data-type="number" order="{$order}"/>
         <xsl:if test="position() = 1">
            <xsl:value-of select="concat(substring(substring-before(substring-after(.,'('),'/'), 1, 100 * ($XorY = 'x')), substring(substring-before(substring-after(.,'/'),')'), 1, 100 * ($XorY = 'y')))"/>
         </xsl:if>
      </xsl:for-each>
   </xsl:template>

   <xsl:template match="@*|node()">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
   </xsl:template>
</xsl:stylesheet>

当应用于您的示例XML时，输出以下内容

<polygon>
   <xMin>2.456</xMin>
   <xMax>8.234</xMax>
   <yMin>5.678</yMin>
   <yMax>9.435</yMax>
</polygon>

如何对元素字符串的一部分进行排序？

1 个答案: