Concat使用递归键入数字

Question

XML编码如下

<math>
  <mn>
    <mphantom>12</mphantom>
  </mn>
</math>

需要输出：

<?xml version='1.0' encoding='UTF-8'?>
<math>|phantom1||phantom2|</math>

XSLT试过：

<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:m="http://www.w3.org/1998/Math/MathML"
  xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
  xmlns:cl="http://xml.cengage-learning.com/cendoc-core"
  xmlns:mml="http://www.w3.org/1998/Math/MathML"
  xmlns:xlink="http://www.w3.org/1999/xlink">
    <xsl:output method="xml" encoding="UTF-8" indent="no" />
    <xsl:strip-space elements="*" />

    <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()" />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="mn">
        <xsl:variable name="pText" select="." />
        <xsl:variable name="numst" select="2" />
        <xsl:choose>
            <xsl:when test="not(string-length($pText))&gt;0">
                <xsl:value-of select="$pText" />
            </xsl:when>
            <xsl:otherwise>
                <xsl:variable name="ConcatStr" select="substring($pText,$numst)" />
                <xsl:variable name="FinalStr" select="substring-before($pText,$ConcatStr)" />
                <xsl:text disable-output-escaping="yes">|phantom</xsl:text>
                <xsl:value-of select="$FinalStr" />
                <xsl:text disable-output-escaping="yes">|</xsl:text>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

    <xsl:template match="mphantom">
        <xsl:apply-templates />
    </xsl:template>

</xsl:stylesheet>

我使用上面的XSLT进行转换，但我只得到第一个数字。但我需要将它用作递归。我正在使用XSLT 1.0。请建议

Answer 1

试试这个..

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output indent="yes" omit-xml-declaration="yes" />
<xsl:strip-space elements="*" />

<xsl:template match="@*|node()">
  <xsl:copy>
    <xsl:apply-templates select="@*|node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="mn[mphantom]" name="phant">
  <xsl:param name="chars" select="mphantom" />
  <xsl:value-of select="concat('|phantom',substring($chars,1,1),'|')" />
  <xsl:if test="substring($chars,2)">
    <xsl:call-template name="phant">
      <xsl:with-param name="chars" select="substring($chars,2)" />
    </xsl:call-template>
  </xsl:if>
</xsl:template>

</xsl:stylesheet>

Answer 2

这是一个更简单的非递归解决方案，使用Piez method ：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="mphantom">
     <math>
     <xsl:variable name="vCur" select="."/>
      <xsl:for-each select=
       "(document('')//node()|document('')//@*|document('')//namespace::*)
          [not(position() > string-length($vCur))]
       ">
        <xsl:value-of select="concat('|', substring($vCur, position(), 1),'|')"/>
      </xsl:for-each>
     </math>
 </xsl:template>
</xsl:stylesheet>

在提供的XML文档上应用此转换时：

<math>
    <mn>
        <mphantom>12</mphantom>
    </mn>
</math>

产生了想要的正确结果：

<math>|1||2|</math>

---

<强> II。为了完整起见，这是一个XSLT 2.0解决方案：

<xsl:stylesheet version="2.0"   xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="mphantom">
     <math>
       <xsl:value-of separator="" select=
        "for $i in 1 to string-length()
          return
             concat('|', substring(., $i, 1), '|')
        "/>
     </math>
 </xsl:template>
</xsl:stylesheet>