Question

我想知道是否有人有完整，有效和高效的代码来在glsl中进行双三次纹理过滤。有这个：

http://www.codeproject.com/Articles/236394/Bi-Cubic-and-Bi-Linear-Interpolation-with-GLSL 要么 https://github.com/visionworkbench/visionworkbench/blob/master/src/vw/GPU/Shaders/Interp/interpolation-bicubic.glsl

但是它们都进行了16次纹理读取，其中只需要4次：

https://groups.google.com/forum/#!topic/comp.graphics.api.opengl/kqrujgJfTxo

然而，上面的方法使用了一个缺少的“cubic（）”函数，我不知道它应该做什么，并且还需要一个无法解释的“texscale”参数。

还有NVidia版本：

http://http.developer.nvidia.com/GPUGems2/gpugems2_chapter20.html

但我相信这会使用CUDA，这是专门针对NVidia的卡片。我需要glsl。

我可能将nvidia版本移植到glsl，但我想先问一下是否有人已经有一个完整的，有效的glsl bicubic着色器。

Answer 1

我决定花点时间挖掘旧的Perforce活动并找到缺少的cubic（）函数;请享用！：）

vec4 cubic(float v)
{
    vec4 n = vec4(1.0, 2.0, 3.0, 4.0) - v;
    vec4 s = n * n * n;
    float x = s.x;
    float y = s.y - 4.0 * s.x;
    float z = s.z - 4.0 * s.y + 6.0 * s.x;
    float w = 6.0 - x - y - z;
    return vec4(x, y, z, w);
}

Answer 2

我发现这个实现可以用作texture（）的替代品（来自http://www.java-gaming.org/index.php?topic=35123.0（一个错字修复））：

public class Song extends DigitalMedia {

    private String artist;
    private String album;
    private String name;
    private long size;

    private Song(String aName, long aSize, String aArtist, String aAlbum) {
        super(aName, aSize);
        setArtist(aArtist);
        setAlbum(aAlbum);
    }

    public static Song makeSong(String aName, long aSize, String aArtist, String aAlbum) {
        //... validation code
        return new Song(aName, aSize, aArtist, aAlbum);
    }
    ...
}

示例：最近的，双线性的，双三次的：

此图片的ImageData是

// from http://www.java-gaming.org/index.php?topic=35123.0
vec4 cubic(float v){
    vec4 n = vec4(1.0, 2.0, 3.0, 4.0) - v;
    vec4 s = n * n * n;
    float x = s.x;
    float y = s.y - 4.0 * s.x;
    float z = s.z - 4.0 * s.y + 6.0 * s.x;
    float w = 6.0 - x - y - z;
    return vec4(x, y, z, w) * (1.0/6.0);
}

vec4 textureBicubic(sampler2D sampler, vec2 texCoords){

   vec2 texSize = textureSize(sampler, 0);
   vec2 invTexSize = 1.0 / texSize;

   texCoords = texCoords * texSize - 0.5;


    vec2 fxy = fract(texCoords);
    texCoords -= fxy;

    vec4 xcubic = cubic(fxy.x);
    vec4 ycubic = cubic(fxy.y);

    vec4 c = texCoords.xxyy + vec2 (-0.5, +1.5).xyxy;

    vec4 s = vec4(xcubic.xz + xcubic.yw, ycubic.xz + ycubic.yw);
    vec4 offset = c + vec4 (xcubic.yw, ycubic.yw) / s;

    offset *= invTexSize.xxyy;

    vec4 sample0 = texture(sampler, offset.xz);
    vec4 sample1 = texture(sampler, offset.yz);
    vec4 sample2 = texture(sampler, offset.xw);
    vec4 sample3 = texture(sampler, offset.yw);

    float sx = s.x / (s.x + s.y);
    float sy = s.z / (s.z + s.w);

    return mix(
       mix(sample3, sample2, sx), mix(sample1, sample0, sx)
    , sy);
}

我试图重现这个（许多其他插值技术）

但他们已经夹住填充，而我重复（包裹）边界。因此它并不完全相同。

这种双立方业务似乎不是一个正确的插值，即它不会在定义数据的点处采用原始值。

Answer 3

JAre's answer中缺失的函数cubic()可能如下所示：

vec4 cubic(float x)
{
    float x2 = x * x;
    float x3 = x2 * x;
    vec4 w;
    w.x =   -x3 + 3*x2 - 3*x + 1;
    w.y =  3*x3 - 6*x2       + 4;
    w.z = -3*x3 + 3*x2 + 3*x + 1;
    w.w =  x3;
    return w / 6.f;
}

它返回立方B样条曲线的四个权重。

所有这些都在NVidia Gems中解释。

Answer 4

哇。我认识到上面的代码（我无法评论w /信誉＆lt; 50），因为我在2011年初提出它。我试图解决的问题与旧的IBM T42有关（对不起确切的型号逃脱了我）笔记本电脑它是ATI图形堆栈。我在NV卡上开发了代码，最初我使用了16个纹理提取。对我来说，这有点慢但足够快。当有人报告它在他的笔记本电脑上没有工作时，很明显他们不支持每个片段足够的纹理提取。我不得不设计一个解决方案，我能想到的最好的方法是使用一些可以工作的纹理提取。

我这样想过：好吧，如果我用线性滤波器处理每个四（2x2），剩下的问题是行和列可以共享权重吗？当我开始编写代码时，这是我脑海中唯一的问题。当然他们可以分享;每列和每行的权重相同;完美！

现在我有四个样本。剩下的问题是如何正确组合样本。这是要克服的最大障碍。用铅笔和纸花了大约10分钟。我用颤抖的双手输入代码并且工作正常，很好。然后我把二进制文件上传到承诺在他的T42（？）上查看它的人，他报告说它有效。结束。：）

我可以确保方程式检查并在数学上给出相同的结果来单独计算样本。仅供参考：使用CPU时，单独进行水平和垂直扫描会更快。使用GPU多次通过并不是一个好主意，特别是在典型用例中它可能不可行。

深思熟虑：可以对cubic（）函数使用纹理查找。哪个更快取决于GPU，但一般来说，ALU侧的采样器很轻，只是做算术可以平衡问题。 YMMV。

Answer 5

（编辑）

Cubic（）是cubic spline function

示例：

cubic spline

Texscale是采样窗口大小系数。你可以从1.0值开始。

vec4 filter(sampler2D texture, vec2 texcoord, vec2 texscale)
{
    float fx = fract(texcoord.x);
    float fy = fract(texcoord.y);
    texcoord.x -= fx;
    texcoord.y -= fy;

    vec4 xcubic = cubic(fx);
    vec4 ycubic = cubic(fy);

    vec4 c = vec4(texcoord.x - 0.5, texcoord.x + 1.5, texcoord.y -
0.5, texcoord.y + 1.5);
    vec4 s = vec4(xcubic.x + xcubic.y, xcubic.z + xcubic.w, ycubic.x +
ycubic.y, ycubic.z + ycubic.w);
    vec4 offset = c + vec4(xcubic.y, xcubic.w, ycubic.y, ycubic.w) /
s;

    vec4 sample0 = texture2D(texture, vec2(offset.x, offset.z) *
texscale);
    vec4 sample1 = texture2D(texture, vec2(offset.y, offset.z) *
texscale);
    vec4 sample2 = texture2D(texture, vec2(offset.x, offset.w) *
texscale);
    vec4 sample3 = texture2D(texture, vec2(offset.y, offset.w) *
texscale);

    float sx = s.x / (s.x + s.y);
    float sy = s.z / (s.z + s.w);

    return mix(
        mix(sample3, sample2, sx),
        mix(sample1, sample0, sx), sy);
}

Source

Answer 6

对于任何对GLSL代码感兴趣的人进行三 - 立方插值，可以在examples / glCubicRayCast文件夹中找到使用三次插值的光线投射代码： http://www.dannyruijters.nl/cubicinterpolation/CI.zip

编辑：立方插值代码现在可在github上使用：CUDA版本和WebGL版本以及GLSL样本。

Answer 7

我一直使用@Maf的三次样条配方超过一年，如果立方B样条符合您的需要，我推荐它。

但是我最近意识到，对于我的特定应用，强度恰好与样本点匹配非常重要。所以我改用了Catmull-Rom样条，它使用了一个略有不同的配方，如下所示：

// Catmull-Rom spline actually passes through control points
vec4 cubic(float x) // cubic_catmullrom(float x)
{
    const float s = 0.5; // potentially adjustable parameter
    float x2 = x * x;
    float x3 = x2 * x;
    vec4 w;
    w.x =    -s*x3 +     2*s*x2 - s*x + 0;
    w.y = (2-s)*x3 +   (s-3)*x2       + 1;
    w.z = (s-2)*x3 + (3-2*s)*x2 + s*x + 0;
    w.w =     s*x3 -       s*x2       + 0;
    return w;
}

我在以下讲义中找到了这些系数，以及其他一些三次样条的系数。 http://www.cs.cmu.edu/afs/cs/academic/class/15462-s10/www/lec-slides/lec06.pdf

Answer 8

我认为Catmull版本可以通过4种纹理查找来完成，方法是（a）将输入纹理排列成象棋盘一样，另存为正和负的插槽，以及（b）关联的TextureBicubic修改。这将取决于贡献/权重w.x / w.w始终为负，而贡献w / y / w.z始终为正。我还没有仔细检查这是否是真的，或者修改后的textureBicubic看起来究竟是什么样。

...我已验证w贡献确实满足+ ve -ve规则。

GLSL中的高效双立方过滤代码？

8 个答案: