Question

我需要Air / Flex应用程序中当前登录用户的名称。该应用程序仅部署在Windows计算机上。我想我可以通过重新编写用户目录来达到这个目的，但我可以采用其他方式。

Answer 1

你可以做几个小清理......

package
{
    import flash.filesystem.File;

    public class UserUtil
    {
        public static function get currentOSUser():String
        {
            var userDir:String = File.userDirectory.nativePath;
            var userName:String = userDir.substr(userDir.lastIndexOf(File.separator) + 1);
            return userName;
        }
    }
}

正如凯文建议的那样，使用File.separator使目录分割跨平台（仅在Windows和Mac OS X上测试）。

除非您正在寻找孩子，否则无需使用resolvePath("")。

此外，使该功能成为一个合适的吸气剂允许在没有任何进一步工作的情况下进行绑定。

在上面的示例中，我将其放入UserUtil类，现在我可以绑定到UserUtil.currentOSUser，例如：

<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute">
    <mx:Label text="{UserUtil.currentOSUser}"/> 
</mx:WindowedApplication>

Answer 2

我也会尝试：

File.userDirectory.name

但是我没有安装Air，所以我无法真正测试这个......

Answer 3

这不是最漂亮的方法，但如果您知道您的AIR应用程序只能在Windows环境中运行，那么它的效果就足够了：

public var username:String;

public function getCurrentOSUser():void
{       
   var nativeProcessStartupInfo:NativeProcessStartupInfo = new NativeProcessStartupInfo();  
   var file:File = new File("C:/WINDOWS/system32/whoami.exe");
   nativeProcessStartupInfo.executable = file;

   process = new NativeProcess();       
   process.addEventListener(ProgressEvent.STANDARD_OUTPUT_DATA, onOutputData);
   process.start(nativeProcessStartupInfo);
}

public function onOutputData(event:ProgressEvent):void
{           
   var output:String = process.standardOutput.readUTFBytes(process.standardOutput.bytesAvailable);
   this.username = output.split('\\')[1];
   trace("Got username: ", this.username);
}

Answer 4

这是一个适用于XP / Vista的解决方案，但绝对可以扩展到OSX，linux，我仍然会对另一种方式感兴趣。

public static function GetCurrentOSUser():String{
    // XP & Vista only.
    var userDirectory:String = File.userDirectory.resolvePath("").nativePath;
    var startIndex:Number = userDirectory.lastIndexOf("\\") + 1
    var stopIndex:Number = userDirectory.length;
    var user = userDirectory.substring(startIndex, stopIndex);

    return user;
}

Answer 5

稍后更新方式：实际上有一个内置函数来获取当前用户。我认为它在nativeApplication中。

获取Adobe Air中当前登录的OS用户

5 个答案: