有没有办法从Oracle中的PL / SQL刷新输出？

Question

我有一个从shell脚本中调用的SQL脚本，需要很长时间才能运行。它目前在各个点包含dbms_output.put_line个语句。这些打印语句的输出显示在日志文件中，但只有在脚本完成后才会出现。

有没有办法确保在脚本运行时输出显示在日志文件中？

Answer 1

不是真的。 DBMS_OUTPUT的工作方式是：您的PL / SQL块在数据库服务器上执行而不与客户端交互。因此，当您调用PUT_LINE时，它只是将该文本放入服务器内存中的缓冲区中。当你的PL / SQL块完成时，控制权返回给客户端（在这种情况下我假设是SQLPlus）;此时，客户端通过调用GET_LINE将文本从缓冲区中取出，然后显示它。

因此，更频繁地使输出显示在日志文件中的唯一方法是将大型PL / SQL块拆分为多个较小的块，以便更频繁地将控制权返回给客户端。根据您的代码正在做什么，这可能不切实际。

其他替代方法是使用UTL_FILE写入文本文件，可以随时刷新，也可以使用自治事务过程将调试语句插入数据库表并在每个文件表后提交。

Answer 2

两种选择：

1. 您可以使用自治事务在日志记录表中插入日志记录详细信息。您可以在另一个SQLPLUS / Toad / sql开发人员等会话中查询此日志记录表。您必须使用自治事务才能在不干扰主sql脚本中的事务处理的情况下提交日志记录。

2. 另一种方法是使用管道函数返回您的日志记录信息。请看这里的示例：http://berxblog.blogspot.com/2009/01/pipelined-function-vs-dbmsoutput.html当您使用流水线函数时，您不必使用另一个SQLPLUS / Toad / sql开发人员等...会话。

Answer 3

如果可以，您应该用自己的函数替换对dbms_output.put_line的调用。

以下是此功能的代码 WRITE_LOG - 如果您希望能够在2种日志记录解决方案中进行选择：

将日志写入 autonomous transaction

中的表格

CREATE OR REPLACE PROCEDURE to_dbg_table(p_log varchar2)
  -- table mode: 
  -- requires
  -- CREATE TABLE dbg (u varchar2(200)   --- username
  --                 , d timestamp       --- date
  --                 , l varchar2(4000)  --- log 
  -- );
AS
   pragma autonomous_transaction;
BEGIN
  insert into dbg(u, d, l) values (user, sysdate, p_log);
  commit;
END to_dbg_table;
/

或直接写入承载数据库的数据库服务器

这使用 Oracle directory TMP_DIR

CREATE OR REPLACE PROCEDURE to_dbg_file(p_fname varchar2, p_log varchar2)
  -- file mode: 
  -- requires
--- CREATE OR REPLACE DIRECTORY TMP_DIR as '/directory/where/oracle/can/write/on/DB_server/';
AS
  l_file utl_file.file_type;
BEGIN
  l_file := utl_file.fopen('TMP_DIR', p_fname, 'A');
  utl_file.put_line(l_file, p_log);
  utl_file.fflush(l_file);
  utl_file.fclose(l_file);
END to_dbg_file;
/

WRITE_LOG

然后 WRITE_LOG 程序可以在两次使用之间切换，或者停用以避免性能损失（g_DEBUG:=FALSE）。

CREATE OR REPLACE PROCEDURE write_log(p_log varchar2) AS
  -- g_DEBUG can be set as a package variable defaulted to FALSE
  -- then change it when debugging is required
  g_DEBUG boolean := true;
  -- the log file name can be set with several methods...
  g_logfname varchar2(32767) := 'my_output.log';
  -- choose between 2 logging solutions:
  -- file mode: 
  g_TYPE varchar2(7):= 'file';
  -- table mode: 
  --g_TYPE varchar2(7):= 'table';
  -----------------------------------------------------------------
BEGIN
  if g_DEBUG then
    if g_TYPE='file' then
      to_dbg_file(g_logfname, p_log);
    elsif g_TYPE='table' then
      to_dbg_table(p_log);
    end if;
  end if;  
END write_log;
/

以下是如何测试上述内容：

1）从您的SQLPLUS中启动此（文件模式）：

BEGIN
  write_log('this is a test');
  for i in 1..100 loop
    DBMS_LOCK.sleep(1);
    write_log('iter=' || i);
  end loop;
  write_log('test complete');
END;
/

2）在数据库服务器上，打开一个shell并

    tail -f -n500 /directory/where/oracle/can/write/on/DB_server/my_output.log

Answer 4

在调用过程DBMS_OUTPUT时读取DBMS_OUTPUT.get_line的缓冲区。如果您的客户端应用程序是SQL * Plus，则意味着只有在过程完成后才会刷新它。

您可以应用this SO中描述的方法将DBMS_OUTPUT缓冲区写入文件。

Answer 5

使用dbms_application_info()设置会话元数据MODULE和/或ACTION。
使用OEM进行监视，例如：

Module: ArchiveData
Action: xxx of xxxx

Answer 6

如果您可以从PL / SQL环境访问系统shell，则可以调用netcat：

 BEGIN RUN_SHELL('echo "'||p_msg||'" | nc '||p_host||' '||p_port||' -w 5'); END;

p_msg - 是一条日志消息 v_host是运行python脚本的主机，它从端口v_port上的套接字读取数据。

当我为实时shell和pl / sql日志监控编写aplogr时，我使用了这个设计。