Question

我有一个如下所示的SAS数据集：

id | dept | ...
1    A
2    A
3    A
4    A
5    A
6    A
7    A
8    A
9    B
10   B
11   B
12   B
13   B

每次观察代表一个人。

我想将数据集拆分为“团队”数据集，每个数据集最多可以有3个观察数据。

对于上面的示例，这将意味着为dept A创建3个数据集（其中2个数据集将包含3个观测值，第三个数据集将包含2个观测值）。和部门B的2个数据集（1个包含3个观测值，另一个包含2个观测值）。

像这样：

第一个数据集（deptA1）：

id | dept | ...
1    A
2    A
3    A

第二个数据集（deptA2）

id | dept | ...
4    A
5    A
6    A

第三个数据集（deptA3）

id | dept | ...
7    A
8    A

第四个数据集（deptB1）

id | dept | ...
9    B
10   B
11   B

第五个数据集（deptB2）

id | dept | ...
12   B
13   B

我使用的完整数据集包含数以千计的观察结果，包含50多个部分。我可以计算出每个部门需要多少数据集，我认为宏是最好的方法，因为所需的数据集数量是动态的。但我无法弄清楚创建数据集的逻辑，以便它们最多有3个观测值。任何帮助表示赞赏。

Answer 1

你可以试试这个：

%macro split(inds=,maxobs=);

  proc sql noprint;
    select distinct dept into :dept1-:dept9999
    from &inds.
    order by dept;
    select ceil(count(*)/&maxobs.) into :numds1-:numds9999
    from &inds.
    group by dept
    order by dept;
  quit;
  %let numdept=&sqlobs;

  data %do i=1 %to &numdept.;
         %do j=1 %to &&numds&i;
           dept&&dept&i&&j.
         %end;
       %end;;
    set &inds.;
    by dept;
    if first.dept then counter=0;
    counter+1;
    %do i=1 %to &numdept.;
      %if &i.=1 %then %do;
        if
      %end;
      %else %do;
        else if
      %end;
                dept="&&dept&i" then do;
      %do k=1 %to &&numds&i.;
        %if &k.=1 %then %do;
          if
        %end;
        %else %do;
          else if
        %end;
                 counter<=&maxobs.*&k. then output dept&&dept&i&&k.;
      %end;
      end;
    %end;
  run;
%mend split;

%split(inds=YOUR_DATASET,maxobs=3);

只需将％SPLIT宏调用中的INDS参数值替换为输入数据集的名称。

Answer 2

另一个版本。与DavB版本相比，它只处理输入数据一次，并将其分成单个datastep中的几个表。此外，如果需要更复杂的拆分规则，可以在datastep视图WORK.SOURCE_PREP中实现。

data WORK.SOURCE;
infile cards;
length ID 8 dept $1;
input ID dept;
cards;
1    A
2    A
3    A
4    A
5    A
6    A
7    A
8    A
9    B
10   B
11   B
12   B
13   B
14   C
15   C
16   C
17   C
18   C
19   C
20   C
;
run;

proc sort data=WORK.SOURCE;
by dept ID;
run;

data  WORK.SOURCE_PREP / view=WORK.SOURCE_PREP;
set WORK.SOURCE;
by dept;
length table_name $32;

if first.dept then do;
    count = 1;
    table = 1;
end;
else count + 1;

if count > 3 then do;
    count = 1;
    table + 1;
end;
/* variable TABLE_NAME to hold table name */
TABLE_NAME = catt('WORK.', dept, put(table, 3. -L));
run;

/* prepare list of tables */
proc sql noprint;
create table table_list as
select distinct TABLE_NAME from WORK.SOURCE_PREP where not missing(table_name)
;
%let table_cnt=&sqlobs;
select table_name into :table_list separated by ' ' from table_list;
select table_name into :tab1 - :tab&table_cnt from table_list;
quit;

%put &table_list;

%macro loop_when(cnt, var);
    %do i=1 %to &cnt;
        when ("&&&var.&i") output &&&var.&i;
    %end;
%mend;

data &table_list;
set WORK.SOURCE_PREP;
    select (TABLE_NAME);
        /* generate OUTPUT statements */
        %loop_when(&table_cnt, tab)
    end;
run;

拆分SAS数据集

2 个答案: