Question

阅读this page后。我发现很难记住如何使用define-syntax代替define-macro，所以我想在mit-scheme中实现define-macro（或者至少找到一些等价物）。

这是我的（有问题的）实施：

(define-syntax define-macro
  (rsc-macro-transformer
    (let ((xfmr (lambda (macro-name macro-body)
      (list 'define-syntax macro-name
        (list 'rsc-macro-transformer
          (let ((m-xfmr macro-body))
            (lambda (e r)
              (apply m-xfmr (cdr e)))))))))
      (lambda (e r)
        (apply xfmr (cdr e))))))

(define-macro my-when
  (lambda (test . branch)
    (list 'if test (cons 'begin branch))))

(my-when #t
  (begin
    (display "True")
    (newline)))

REPL抱怨道：

;The object (lambda (test . branch) (list (quote if) test (cons (quote begin) branch))) is not applicable.

我是计划新手并不知道出了什么问题，有人可以帮帮我吗？

Answer 1

首先，您应该学会使用准规则，这样您的宏更容易阅读。像这样：

(define-macro (my-when test . branch)
  `(if ,test
     (begin ,@branch)))

更严重的是，使用syntax-rules编写这一点非常容易，而且你真的应该更喜欢define-macro。

(define-syntax-rule (my-when test branch ...)
  (if test
    (begin branch ...)))

哦，你以前没见过define-syntax-rule？这是一个简单的宏，可用于编写单子句define-syntax宏，并且定义如下：

(define-syntax define-syntax-rule
  (syntax-rules ()
    ((define-syntax-rule (name . pattern) template)
     (define-syntax name
       (syntax-rules ()
         ((name . pattern) template))))))

请注意，使用define-syntax-rule，简单的宏变得非常容易编写。这是另一个例子：

(define-syntax-rule (let ((name value) ...)
                      expr ...)
  ((lambda (name ...)
     expr ...)
   value ...))

Answer 2

如果你真的需要define-macro语义，你可以在mit-scheme中得到一个合理的近似值，如下所示：

(define-syntax define-macro
  (syntax-rules ()
    ((define-macro (name . args) body ...)
     (define-syntax name
       (rsc-macro-transformer
         (let ((transformer (lambda args body ...)))
           (lambda (exp env)
              (apply transformer (cdr exp)))))))))

然后你可以将my-when定义为：

(define-macro (my-when test . branch)
  `(if ,test (begin ,@branch)))

是否有可能在mit-scheme中实现“define-macro”

2 个答案: