Question

我正在编写一些MIPS代码来获取一串ASCII数字并将字符串转换为整数。该字符串由用户输入，长度最多为10位。我的代码工作正常并使用明显的方法执行循环加法后，将字符串中的最低有效数乘以由数组索引确定的10的幂，从输入的最后一位数（10 ^ 0）到第一位数输入（10 ^ n，n =数组中的位数）。

我想知道是否有一种替代方法可以更快或更短地编写。特别是，我想知道使用逻辑位移可能会缩短此过程。任何有关优化或改进此代码的想法都将不胜感激！

另外，作为旁注，我想使用jal调用gets和readInt子例程，但因为gets和readInt都调用子例程，在main方法中使用jal调用gets或readInt会导致问题。任何想法如何解决这个问题？再次感谢干杯

PS：对不起这段代码中注释的格式化，从MARS模拟器复制并粘贴到堆栈溢出文本框导致对齐关闭：/

#IO
#Prompts user to input 10 ascii digits into an array
#Converts the string of digits into a single int
#Also handles any number of digits between 1 and 10 
#Returns 0 if non-digit chars are entered into the string

.data           #declaration of vars follows
array: .space 11    #reserves space for a 10 elem array
char: .space 2
prompt: .asciiz "Please enter 10 numbers, then press ENTER:  \n"
null: .asciiz ""
space: .ascii " "
newline: .asciiz "\n"
.text           #instructions follow

main:
la $a0, prompt      #load prompt message into $a0 for syscall
li $v0, 4               #load syscall to print string
syscall         #print prompt message
j readInt               #call readInt function to get user input string         

gets:           #read multiple chars from keyboard buffer until ENTER key,
                            #add NULL char and store into buffer pointed to by *array
                            #passed to the subroutine
la $s1, array       #set base address of array to s1
loop:           #start of read loop
jal getc        #jump to getc subroutine
lb $t0, char        #load the char from char buffer into t0, stripping null
sb $t0, 0($s1)      #store the char into the nth elem of array
lb $t1, newline     #load newline char into t1
beq $t0, $t1, done  #end of string?  jump to done
addi $s1, $s1, 1    #increments base address of array
j loop          #jump to start of read loop

getc:           #read char from keyboard buffer and return ascii value
li $v0, 8       #call code for read string
la $a0, char        #load address of char for read
li $a1, 2       #length of string is 1byte char and 1byte for null
syscall         #store the char byte from input buffer into char
jr $ra          #jump-register to calling function

readInt:        #read string of ascii digits, store into a local variable and  
                    #convert into integer, return that int unless string contains 
                    #non-integers 
j gets          #let s1 be top address of array, let s0 be the digitcounter
done:           #let s2 be the sum total
addi $s1, $s1, -1   #reposition array pointer to last char before newline char
la $s0, array       #set base address of array to s0 for use as counter
addi $s0, $s0, -1   #reposition base array to read leftmost char in string
add $s2, $zero, $zero   #initialize sum to 0
li $t0, 10      #set t0 to be 10, used for decimal conversion
li $t3, 1
lb $t1, 0($s1)      #load char from array into t1
blt $t1, 48, error  #check if char is not a digit (ascii<'0')
bgt $t1, 57, error  #check if char is not a digit (ascii>'9')
addi $t1, $t1, -48  #converts t1's ascii value to dec value
add $s2, $s2, $t1   #add dec value of t1 to sumtotal
addi $s1, $s1, -1   #decrement array address
lp:         #loop for all digits preceeding the LSB
mul $t3, $t3, $t0   #multiply power by 10
beq $s1, $s0, FIN   #exit if beginning of string is reached
lb $t1, ($s1)       #load char from array into t1
blt $t1, 48, error  #check if char is not a digit (ascii<'0')
bgt $t1, 57, error  #check if char is not a digit (ascii>'9')
addi $t1, $t1, -48  #converts t1's ascii value to dec value
mul $t1, $t1, $t3   #t1*10^(counter)
add $s2, $s2, $t1   #sumtotal=sumtotal+t1
addi $s1, $s1, -1   #decrement array address
j lp            #jump to start of loop

error:          #if non digit chars are entered, readInt returns 0
add $s2, $zero, $zero
j FIN

FIN:
li $v0, 1
add $a0, $s2, $zero
syscall 
li $v0, 10      #ends program
syscall

Answer 1

通过使用0x0F和字符串对字符串进行掩码，如下所示

andi $t0,$t0,0x0F # where $t0 contains the ascii digit .

现在$t0有int。

Answer 2

假设$s1指向以NULL结尾的字符串的开头（即最重要的数字），$t0包含10，$s2包含0：

lp:         
  lbu $t1, ($s1)       #load unsigned char from array into t1
  beq $t1, $0, FIN     #NULL terminator found
  blt $t1, 48, error   #check if char is not a digit (ascii<'0')
  bgt $t1, 57, error   #check if char is not a digit (ascii>'9')
  addi $t1, $t1, -48   #converts t1's ascii value to dec value
  mul $s2, $s2, $t0    #sum *= 10
  add $s2, $s2, $t1    #sum += array[s1]-'0'
  addi $s1, $s1, 1     #increment array address
  j lp                 #jump to start of loop

每次迭代只有mul个，并且在进入循环之前无需知道字符串的长度。

Answer 3

针对在嵌套调用中使用jal的问题，您可以只保存$ra中的寄存器（这是在调用jal时用于存储返回地址的寄存器）首次输入第一个电话时；当您拨打Alst电话时，可以正常使用$ra。

main:
    jal call1

call1:
    add $s0, $ra, 0
    ...
    jal call2
    ...
    jr $s0 # will be where $ra was when call 1 was implemented

call2:
    ...
    jr $ra

使用s寄存器可能是最安全的，但是我也能够使用t寄存器。

在MIPS /汇编程序中将ASCII数字字符串转换为int

3 个答案: