Question

在OCaml中，我正在处理模块和仿函数。

我为输入模块和仿函数设置了签名和结构。然后我使用上面的模块制作了一个新模块。事实证明我的新模块不包含输入模块中的函数。

我是否应该能够在我的新模块中使用功能？顺便说一下，仿函数中的函数工作得很好。另外，如何确定它是否是有效的模块？

Answer 1

让我们举一个真实的例子：

module type MONAD = sig
  type 'a t
  val return : 'a -> 'a t
  val (>>=) : 'a t -> ('a -> 'b t) -> 'b t
end

module MonadOps (M : MONAD) = struct
  open M (* values from M visible in scope *)
  let rec mapM f = function
    | [] -> return []
    | x::xs ->
        f x >>= fun y -> 
        mapM f xs >>= fun ys ->
        return (y :: ys)
end

module Option = struct
  type 'a t = 'a option
  let return x = Some x
  let (>>=) m f = match m with
    | None -> None
    | Some x -> f x
end

module OptionOps = MonadOps(Option)

let test = OptionOps.mapM
(* val test : ('a -> 'b Option.t) -> 'a list -> 'b list Option.t = <fun> *)
let test = OptionOps.return x
(* Error: Unbound value OptionOps.return *)

仿函数MonadOps提供了一些构建在任何monad之上的通用功能，但它本身并不包含基本monad功能。它提供额外的东西而不包括现有的东西。

您可以使用include项来更改它，以便在定义的模块值中包含现有模块的内容：

module MonadOps (M : MONAD) = struct
  include M (* values from m *included* in the module *)
  let rec mapM f = function
    [...]
end

但是，我不一定建议这样做。在某些情况下，您正在介入一些方便的冗余（例如，如果您只想open只有一个模块并且具有范围内的所有内容），但也可以在其他情况下产生一些问题，例如。如果你想要组合两个模块扩展仿函数，你必须想知道应用它们的顺序，你可能会遇到奇怪的模块系统hackery。 ML模块系统内部是复杂的野兽，我建议您保持简单使用，避免碰到角落。

请注意，通过不将M包含在仿函数中，您可以随时让仿函数用户选择执行此操作：如果您决定将其直接包含在仿函数中，则可以选择更多选项。我使用这种仿函数的方式就像

(* file 'option.ml' *)
type 'a option = None | Some of 'a

module Monad = struct
  ...
end

module Ops = MonadOps(Monad)

include (Monad : MONAD with type 'a t := 'a option)
include Ops

Answer 2

在更简单的设置中，可以使用M限定符（对于任何模块）访问绑定在仿函数F中的模块M.导出的任何值：

(* out there M does not exist *)
module F (M : sig val v : int end) =
struct
    (* in there M is defined *)
    let m_v = M.v
end

或在open M的任何访问值之前使用M。

module  F (M : sig val v : int end) =
struct
    open M
    let m_v = v
end

如果您想从M生成的模块中获取F的值，则必须以某种方式将其导出：

直接通过在新模块中对M的某些值进行别名
```
module F (...) = struct
    let v = M.v
end
```
将整个模块包括在内
```
module F (...) = struct
    include M
end
```
没有必要始终可以或容易使用包含，因为您可能希望定义与M中的其他类型冲突的类型名称。

使模块成为新模块的一部分

module F (....) = struct
    module M' = M
end

module G = F(struct let v = 5 end);;
print_int G.M.v;;

包括或不包括？它取决于仿函数的客户端，以及生成的模块的客户端。您可能只处理一个程序，该程序必须只知道生成的模块，或者只知道仿函数。如果模块M的内容是操作模块G所必需的，那么您必须以某种方式提供M。

OCaml使用参数化模块

2 个答案: