Question

我有一个名为xxx_blabla_1的文件我需要的只是通过批处理命令成为xxx_date_1，但它必须采用一些不寻常的日期格式：Jan0113，其中Jan是月，01是日，13是年。几个月总是前三个字母。

所以最终结果应该是：xxx_Jan0113_1

Answer 1

我不知道如何重命名，但这是你要做的日期：

  %date:~3,2% + %date:~0,2% + %date:~8,2%

这将返回：010113

Answer 2

@echo off
setlocal EnableDelayedExpansion

rem Define month names array (with 2-digits subscripts)
set m=100
for %%a in (Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec) do (
   set /A m+=1
   set month[!m:~-2!]=%%a
)

rem Get today's date parts
for /F "tokens=1-3 delims=/" %%a in ("%date%") do (
   set dd=%%a
   set mm=%%b
   set yyyy=%%c
)

rem Do the rename
ren xxx_blabla_1 xxx_!month[%mm%]!%dd%%yyyy:~-2%

Answer 3

试试这个：

 @echo off
 setlocal
 set filename=xxx_blabla_1
 for /f "tokens=1-3 delims=/" %%a in ('echo 30/04/2013') do (
    set day=%%a
    set year=%%c
  )
 for /f "tokens=1,3 delims=_" %%a in ("%filename%") do (
    set first=%%a
    set third=%%b
  )
 for /f "tokens=2 delims=/" %%i in (
    'echo 30/04/2013') do set/a mnth=1%%i-100
 set year=%year:~2,2%
 for /f "tokens=%mnth%" %%i in (
  "DEC JAN FEB MAR APR MAY JUN JUL AUG SEP OCT NOV") do (
   echo ren %filename% %first%_%%i%day%%year%_%third%)

你可以用'echo％date％'替换'echo 30/04/13'。我不得不硬编码，因为我的日期格式与你的不同。如果您将所需的结果打印到屏幕上，请在渲染之前删除回声以实际执行操作。

Answer 4

@ECHO OFF
SETLOCAL
:: date format (given) is dd/mm/yy

SET "newbla=01Jan02Feb03Mar04Apr05May06Jun07Jul08Aug09Sep10Oct11Nov12Dec"
CALL SET newbla=%%newbla:*%date:~3,2%=%%

SET oldname=xxx_blabla_1.whatever
CALL SET newbla=%%oldname:blabla=%newbla:~0,3%%date:~0,2%%date:~6,2%%%
ECHO REN "%oldname%" "%newbla%"

这假设'blabla'在名称中只出现一次。

现在，如果您正在寻找更通用的解决方案，其中_用作分隔符：

@ECHO off
SETLOCAL
SET oldname1=xxx_blabla_1.whatever
SET oldname2=yyy_albalb_9.whatever

:: date format (given) is dd/mm/yy

SET "newbla=01Jan02Feb03Mar04Apr05May06Jun07Jul08Aug09Sep10Oct11Nov12Dec"
CALL SET newbla=%%newbla:*%date:~3,2%=%%
SET newbla=%newbla:~0,3%%date:~0,2%%date:~6,2%

FOR /f "tokens=1*delims==" %%m IN ('set oldname') DO (
 FOR /f "tokens=1,2*delims=_" %%a IN ("%%n") DO (
  SET oldname=%%a_%%b_%%c
  CALL SET newname=%%oldname:%%b=%newbla%%%
  SETLOCAL enabledelayedexpansion
  ECHO REN "!oldname!" "!newname!"
  endlocal
 )
)
GOTO :eof

for/f ... %%m...模拟dir /b...列表的位置。

Answer 5

谢谢大家。

我找到了一些我用过它的工具，就是这样。忘了在这篇文章中更新它：）

按日期重命名文件 - 批处理

5 个答案: