Question

给出这样的文件：

a
b
a
b

我希望能够使用sed来替换文件中包含“a”实例的最后一行。因此，如果我想用“c”替换它，那么输出应该如下：

a
b
c
b

请注意，无论可能遇到多少匹配，或者确切了解所需模式或文件内容的详细信息，我都需要这样做。提前谢谢。

Answer 1

不仅仅是sed：

tac file | sed '/a/ {s//c/; :loop; n; b loop}' | tac

测试

% printf "%s\n" a b a b a b | tac | sed '/a/ {s//c/; :loop; n; b loop}' | tac
a
b
a
b
c
b

反转文件，然后进行第一次匹配，进行替换，然后无条件地填充文件的其余部分。然后重新反转文件。

注意，空正则表达式（此处为s//c/）表示重用前一个正则表达式（/a/）

除了非常简单的节目，我不是一个巨大的sed粉丝。我会用awk：

tac file | awk '/a/ && !seen {sub(/a/, "c"); seen=1} 1' | tac

Answer 2

这可能适合你（GNU sed）：

sed -r '/^PATTERN/!b;:a;$!{N;/^(.*)\n(PATTERN.*)/{h;s//\1/p;g;s//\2/};ba};s/^PATTERN/REPLACEMENT/' file

或其他方式：

sed '/^PATTERN/{x;/./p;x;h;$ba;d};x;/./{x;H;$ba;d};x;b;:a;x;/./{s/^PATTERN/REPLACEMENT/p;d};x' file

或者如果您愿意：

sed -r ':a;$!{N;ba};s/^(.*\n?)PATTERN/\1REPLACEMENT/' file

经过反思，这个解决方案可能会取代前两个：

sed  '/a/,$!b;/a/{x;/./p;x;h};/a/!H;$!d;x;s/^a$/c/M' file

如果正则表达式无法在文件中找到，则文件将保持不变。正则表达式匹配后，所有行都将存储在保留空间中，并在满足一个或两个条件时打印。如果遇到后续的正则表达式，则会打印保留空间的内容，并且最新的正则表达式将替换它。在文件末尾，保留空间的第一行将保留最后一个匹配的正则表达式，并且可以替换它。

Answer 3

这里有很多好的答案;这是一个概念上简单的两遍sed解决方案，由tail辅助 POSIX兼容，并且不会将整个文件读入内存，类似于Eran Ben-Natan's approach：

sed "$(sed -n '/a/ =' file | tail -n 1)"' s/a/c/' file

sed -n '/a/=' file输出匹配正则表达式=的行（函数a）的数字，tail -n 1提取输出的< em> last 行，即包含正则表达式的 last 出现的文件file中的行号。
在$(sed -n '/a/=' file | tail -n 1)之前直接放置命令替换' s/a/c'会导致外部sed脚本，例如3 s/a/c/（带有示例输入），执行所需的替换仅在正则表达式发生的最后一次。

如果在输入文件中找不到模式，则整个命令是有效的无操作。

Answer 4

另一个：

tr '\n' ' ' | sed 's/\(.*\)a/\1c/' | tr ' ' '\n'

行动中：

$ printf "%s\n" a b a b a b | tr '\n' ' ' | sed 's/\(.*\)a/\1c/' | tr ' ' '\n'
a
b
a
b
c
b

Answer 5

另一种方法：

sed "`grep -n '^a$' a | cut -d \: -f 1 | tail -1`s/a/c/" a

这种方法的优点是您可以在文件上按顺序运行两次，而不是将其读取到内存中。这在大文件中可能有意义。

Answer 6

缓冲整个输入时的两遍解决方案是不可容忍的：

sed "$(sed -n /a/= file | sed -n '$s/$/ s,a,c,/p' )" file

（这个版本的早期版本遇到了在redhat bash-4.1安装中遇到历史扩展的错误，这样可以避免错误扩展的$!d。）

尽可能少缓冲的一次通过解决方案：

sed '/a/!{1h;1!H};/a/{x;1!p};$!d;g;s/a/c/'

最简单的：

tac | sed '0,/a/ s/a/c/' | tac

Answer 7

以下所有内容均在一个awk

中完成

awk 'FNR==NR {if ($0~/a/) f=NR;next} FNR==f {$0="c"} 1' file file
a
b
c
b

这会两次读取文件。首先运行以查找最后a，第二次运行以更改它。

Answer 8

tac infile.txt | sed "s/a/c/; ta ; b ; :a ; N ; ba" | tac

第一个tac反转infile.txt的行，sed表达式（请参阅https://stackoverflow.com/a/9149155/2467140）将'a'的第一个匹配替换为'c'并打印剩下的行，最后一行tac将行反转回原来的顺序。

Answer 9

以下是仅使用awk的方法：

awk '{a[NR]=$1}END{x=NR;cnt=1;while(x>0){a[x]=((a[x]=="a"&&--cnt==0)?"c <===":a[x]);x--};for(i=1;i<=NR;i++)print a[i]}' file

$ cat f
a
b
a
b
f
s
f
e
a
v
$ awk '{a[NR]=$1}END{x=NR;cnt=1;while(x>0){a[x]=((a[x]=="a"&&--cnt==0)?"c <===":a[x]);x--};for(i=1;i<=NR;i++)print a[i]}' f
a
b
a
b
f
s
f
e
c <===
v

Answer 10

也可以在perl中完成：

perl -e '@a=reverse<>;END{for(@a){if(/a/){s/a/c/;last}}print reverse @a}' temp > your_new_file

测试：

> cat temp
a
b
c
a
b
> perl -e '@a=reverse<>;END{for(@a){if(/a/){s/a/c/;last}}print reverse @a}' temp
a
b
c
c
b
>

Answer 11

这是命令：

sed '$s/.*/a/' filename.txt

这就是行动：

> echo "a
> b
> a
> b" > /tmp/file.txt

> sed '$s/.*/a/' /tmp/file.txt
a
b
a
a

Answer 12

这是另一种选择：

sed -e '$ a a' -e '$ d' file

第一个命令追加a，第二个命令删除最后一行。来自sed(1) man page：

$ 匹配最后一行。

d 删除模式空间。开始下一个周期。

a text 附加文字，其中每个嵌入的换行符都以反斜杠开头。

Answer 13

awk - 只有解决方案：

awk '/a/{printf "%s", all; all=$0"\n"; next}{all=all $0"\n"} END {sub(/^[^\n]*/,"c",all); printf "%s", all}' file

说明：

当一行与a匹配时，之前a最多（不包括）当前a（即存储在变量all中的内容）之间的所有行都是印刷
如果某行与a不匹配，则会将其附加到变量all。
与a匹配的最后一行无法打印其all内容，因此您需要在END块中手动将其打印出来。在此之前，您可以将匹配a的行替换为您想要的任何内容。

Answer 14

假设：

$ cat file
a
b
a
b

您可以使用POSIX grep来计算匹配项：

$ grep -c '^a' file
2

然后将该号码输入awk以打印替换号：

$ awk -v last=$(grep -c '^a' file) '/^a/ && ++cnt==last{ print "c"; next } 1' file
a
b
c
b

sed替换最后一行匹配模式

14 个答案: