Question

我是Groovy＆amp;的新手Grails的。我正在研究Grails中的一对多关系示例。

以下是代码。

class User {

    //properties
    String login
    String password
    String role

    //constraints and order of display of fields in UI
    static constraints = {
        login(blank: false, nullable: false, unique: true)
        password(blank: false, nullable: false, password: true)
        role(inList:["Admin", "Member"])
    }

    static hasMany = [posts : Post]
}


class Post {
    String content
    Date dateCreated

    static constraints = {
        content(blank: true)
    }

    static belongsTo = [user : User]
}

我在Groovy中的测试类

@TestFor(User)
class UserTests {

    void testUserToPost() {

        def user = new User(login: "joe", password: "joe", role:"Admin")
        user.addToPosts(new Post(content: "First"));
        user.addToPosts(new Post(content: "Second"));
        user.addToPosts(new Post(content: "Third"));
        user.save(flush: true)
        assertEquals 3, User.get(user.id).posts.size()

    }
}

在运行测试类时，遇到以下异常：

groovy.lang.MissingMethodException: No signature of method: com.library.forum.User.addToPosts() is applicable for argument types: (com.library.forum.Post) values: [com.library.forum.Post : (unsaved)]
Possible solutions: getPosts() at com.library.forum.UserTests.testUserToPost(UserTests.groovy:17)

任何人都可以告诉我代码中的问题在哪里。

Answer 1

自Grails 2.1.4以来，由于性能问题，模拟行为发生了变化。因此，您需要模拟模拟实体的所有关联实体。

请参阅GRAILS-9637 - 由于性能问题，@Mock不再嘲笑被模拟实体的关联实体。这些必须是手动的指定。例如，以下测试将在2.1.4中失败以上：

@Mock(Author)
void testAddToBooks() {
    def a = new Author()
    a.addToBooks(new Book())
}

要纠正上述测试，您需要模拟作者和书籍：

@Mock([Author, Book])
void testAddToBooks() {
    def a = new Author()
    a.addToBooks(new Book())
}

您可以查看reference。

Answer 2

您需要模拟所有相关的域类。变化：

@TestFor(User)
class UserTests {

到

@TestFor(User)
@Mock(Post)
class UserTests {

如果需要，模拟注释支持类列表，例如：@Mock([Domain1, Domain2, Domain3])

grails抛出异常的一对多映射

2 个答案: