Question

最近，我开始精益求精编程。我在youtube上看到了以下代码，没有编译它的任何错误。但我有一些错误。我感谢任何帮助

program 
  implicit none
  real, parameter :: pi=4*atan(1.0) 
  integer, parameter :: n = 100
  real :: dimension(1:n) :: x, y
  real :: a=0.0, b = 2*pi
  real :: increment
  integer :: i  

  increment = (b-a)/(real(n)-1) 

  x(1)=0.0
  do i =2,n
    x(i) = x(i-1) + increment
  end do

  y = sin(x)

  print *, x(1:5)
  print *, y(1:5)

end program

Answer 1

real :: dimension(1:n) :: x, y是语法错误。用逗号替换第一个::。您可能需要在程序声明中给出一个名称。

Answer 2

你也有行中的混合模式算术

increment = (b-a)/(real(n)-1)

它可能会编译，甚至可能不会影响程序，但是你永远不应该在任何编程语言中使用混合模式算法，因为它会导致奇怪的，很难找到错误。
它应该是这样的：

increment = (b-a)/(real(n)-1.0)

Answer 3

以下是解决@High Performance Mark问题的工作示例的结果。

host system       = (redacted)
compiler version  = GCC version 5.1.0
compiler options  = -fPIC -mmacosx-version-min=10.9.4 -mtune=core2 -Og -Wall -Wextra -Wconversion -Wpedantic -fmax-errors=5
execution command = ./a.out

 Compare mesh points
   1.57017982       1.57080817       1.57143652    
   1.57016802       1.57079625       1.57142460    
 Compare function values at these mesh points
   1622.04211      -84420.7344      -1562.01758    
   1591.57471       13245402.0      -1591.65527

在您找到的演示中有一个糟糕的编程习惯：通过添加步骤（+增量）而不是计算它们（k *增量）来移动网格。问题很普遍，并且会产生严重后果（https://www.ima.umn.edu/~arnold/disasters/patriot.html）。

为了演示您的代码，网格的大小增加到10K点。此外，样本函数从cos x更改为tan x，我们检查pi / 2 = 1.57079633处奇点附近的点。虽然初始值可能会发现网格值的差异微不足道，但函数值的差异是显着的。

（可以通过使用具有精确二进制表示的增量来减少网格误差，如2 ^（ - 13）= 1/8192。）

此处显示代码。编译命令为gfortran -Wall -Wextra -Wconversion -Og -pedantic -fmax-errors=5 demo.f95。运行命令为./a.out。

program demo
    use iso_fortran_env
    implicit none

    real,    parameter :: pi = acos ( -1.0 ) 
    integer, parameter :: n = 10001

    real, dimension ( 1 : n ) :: x, y, z
    real                      :: a = 0.0, b = 2 * pi
    real                      :: increment

    integer :: k, quarter, status

    character ( len = * ), parameter :: c_options = compiler_options( )
    character ( len = * ), parameter :: c_version = compiler_version( )
    character ( len = 255 )          :: host = " ", cmd = " "

!       queries
        call hostnm      ( host, status )
        call get_command ( cmd )

!       write identifiers
        write ( *, '( /, "host system       = ", g0    )' ) trim ( host )
        write ( *, '(    "compiler version  = ", g0    )' ) c_version
        write ( *, '(    "compiler options  = ", g0    )' ) trim ( c_options )
        write ( *, '(    "execution command = ", g0, / )' ) trim ( cmd )

        increment = ( b - a ) / ( n - 1 )
        quarter = n / 4

!       mesh accumulates errors
        x ( 1 ) = 0.0
        do k = 2, n
            x ( k ) = x ( k - 1 ) + increment
        end do
        y = tan ( x )

        print *, 'Compare mesh points'
        print *, x ( quarter : quarter + 2 )

!       better mesh
        x ( 1 ) = 0.0
        do k = 2, n
            x ( k ) = ( k - 1 ) * increment
        end do
        z = tan ( x )
        print *, x ( quarter : quarter + 2 )

        print *, 'Compare function values at these mesh points'
        print *, y ( quarter : quarter + 2 )
        print *, z ( quarter : quarter + 2 )

end program demo

意外的gfortran编译错误

3 个答案: