Question

我在Erlang中有一个元素列表，我正在使用列表：foreach遍历列表中的元素。有没有办法在遍历的中间突破这个“foreach循环”。例如：假设我想在列表[2,4,5,1,2,5]中遇到'1'时再停止遍历列表。我该怎么做？

Answer 1

另一种方法是使用throw和catch：

catch lists:foreach(
        fun(1) ->
                throw(found_one);
           (X) ->
                io:format("~p~n", [X])
        end,
        [2, 4, 5, 1, 2, 5]).

在shell中运行时，输出：

2
4
5
found_one

编辑：根据大众需求，更准确的版本仅捕获您想要捕获的内容：

try lists:foreach(
        fun(1) ->
                throw(found_one);
           (X) ->
                io:format("~p~n", [X])
        end,
        [2, 4, 5, 1, 2, 5])
catch
    throw:found_one ->
        found_one
end.

Answer 2

traverse(Liste) ->
 traverse(Liste, []).

traverse([], Acc) ->
 Acc;    

traverse([1|_], Acc) ->
 Acc;

traverse([H|T], Acc) ->
 % do something useful here maybe?
 traverse(T, Acc).

当然这是非常粗略的例子。

Answer 3

lists模块中有许多不错的功能：

lists:foreach(fun(E) -> do_something(E) end,
    lists:takewhile(fun(E) -> E =/= 1 end, List)).

或更有效但不太好

lists:takewhile(fun(1) -> false;
                   (E) -> do_something(E), true
                end, List)

Answer 4

我遇到同样的问题并通过这种方式解决：

-module(foreach_until).
-export([foreach_until/3]).

foreach_until(Action, L, Judge)     ->
    lists:reverse(foreach_until(Action, L, Judge, []))
    .

foreach_until(_, [], _, Result) ->
    Result
    ;

foreach_until(Action, [H | T], Judge, Result)   ->
    case Judge(H) of 
        true    -> Result;
        false   -> foreach_until(Action, T, Judge, [Action(H) | Result])
    end
    .

以下是一个解释如何使用的示例：

60> foreach_until:foreach_until(fun(X) -> X*X end, [1,2,3,4], fun(X)-> X >= 3 end).
[1,4]

Answer 5

列表：？所有

do_something(A) ->
   case A of 
      1 ->
         false;
      _ ->
         true
   end.

IsCompleted = lists:all(do_something(A), [2, 4, 5, 1, 2, 5]),

每当do_something返回false时都会中断，并在IsCompleted中返回结果。

Erlang：打破列表：foreach“循环”

5 个答案: