Question

我尝试实现表示算术表达式的接口。接口将由java端使用，但整个逻辑都在clojure上。

有：

(defprotocol ExtendsExpression
  (toTree [this]))

(extend-type String
  ExtendsExpression
  (toTree [this] (symbol this)))

(extend-type Number
  ExtendsExpression
  (toTree [this] this))

(definterface Expression
  (toTree []))

(defrecord Expression1 [^String oper arg]
  Expression
  (toTree [this]
    (list (symbol oper) (toTree arg))))


(defrecord Expression2 [^String oper arg1 arg2]
  Expression
  (toTree [this]
    (list (symbol oper) (toTree arg1) (toTree arg2))))

(defrecord Expression3 [^String oper arg1 arg2 arg3]
  Expression
  (toTree [this]
    (list (symbol oper) (toTree arg1) (toTree arg2) (toTree arg3))))

我尝试将其用作：

(toTree (Expression3. "+" "a" "b" (Expression2. "*" "c" "d")))

但我得到了：

IllegalArgumentException No implementation of method: :toTree of protocol: #'user/ExtendsExpression found for class: user.Expression3  clojure.core/-cache-protocol-fn (core_deftype.clj:541)

为什么clojure会尝试为Expression3调用toTree of ExtendsExpression？我希望对于Expression3，它将调用Expression接口的toTree方法。

Answer 1

好的，明白了;）

(defprotocol ExtendsExpression
  (to-tree [this]))

(extend-type String
  ExtendsExpression
  (to-tree [this] (symbol this)))

(extend-type Number
  ExtendsExpression
  (to-tree [this] this))

(definterface Expression
  (toTree []))

(defrecord Expression1 [^String oper arg]
  ExtendsExpression
  (to-tree [this]
    (list (symbol oper) (to-tree arg)))
  Expression
  (toTree [this] (to-tree this)))


(defrecord Expression2 [^String oper arg1 arg2]
  ExtendsExpression
  (to-tree [this]
    (list (symbol oper) (to-tree arg1) (to-tree arg2)))
  Expression
  (toTree [this] (to-tree this)))

(defrecord Expression3 [^String oper arg1 arg2 arg3]
  ExtendsExpression
  (to-tree [this]
    (list (symbol oper) (to-tree arg1) (to-tree arg2) (to-tree arg3)))
  Expression
  (toTree [this] (to-tree this)))

(to-tree (Expression3. "+" "a" "b" (Expression2. "*" "c" "d"))) ;=> (+ a b (* c d))

并且记录实现了Expression接口，因此我可以轻松地从java中调用它们：

(.toTree (Expression3. "+" "a" "b" (Expression2. "*" "c" "d"))) ;=> (+ a b (* c d))

只是检查Expression3实现的接口：

 (-> Expression3 clojure.reflect/reflect :bases pprint)
#{clojure.lang.IHashEq java.io.Serializable clojure.lang.IKeywordLookup
  clojure.lang.IPersistentMap clojure.lang.IRecord java.lang.Object
  user.ExtendsExpression clojure.lang.IObj clojure.lang.ILookup
  user.Expression java.util.Map}

混合definterface和defprotocol

1 个答案: