gnuplot - 不同长度的水平键标题的对齐方式

Question

当水平放置时，我很难对齐不同的关键标题，显然是由于标题的长度不同。

有两个简短的标题（第一和第四）和两个较长的标题（第二和第三），它在最后两个标题之间留下了更大的差距（可能是因为它将它们之间的间隙设置为相同的最大字符串长度） 。我搜索过但发现无法改变这种情况。

简化示例如下所示。任何建议或帮助将不胜感激。

set terminal postscript eps size 5.12,2.3 enhanced color "Helvetica" 12
set output 'example.eps'

set title 'Difficulty of Long and Short Title usage in Horizontal Keys' font "Helvetica, 20"

set key inside bottom center horizontal font "Helvetica, 20" width 1.8

set ylabel 'ylabel' font "Helvetica, 20" 
set xlabel 'xlabel' font "Helvetica, 20"  
set lmargin screen 0.10
set rmargin screen 0.95
set yrange [-1.5:1.5]

plot sin(x) title 'short', \
cos(x) title 'long title 1', \
-0.5 title 'long title 2', \
0.5 title 'short' w l ls 4

结果是：

Answer 1

一种可能的解决方法是在multiplot模式下生成前三个图形，最后一个图形具有两个不同的绘图命令：

set terminal postscript eps size 5.12,2.3 enhanced color "Helvetica" 12
set output 'example.eps'

set title 'Difficulty of Long and Short Title usage in Horizontal Keys' font "Helvetica, 20"

set ylabel 'ylabel' font "Helvetica, 20" 
set xlabel 'xlabel' font "Helvetica, 20"  
set lmargin screen 0.10
set rmargin screen 0.95
set yrange [-1.5:1.5]

set bmargin screen 0.15
set tmargin screen 0.9

set multiplot
set key horizontal font "Helvetica, 20" width 1.8 at graph 0.4, graph 0.1 center maxrows 1
plot sin(x) title 'short', \
     cos(x) title 'long title 1', \
     -0.5 title 'long title 2'

unset title
unset xlabel
unset ylabel
unset border
unset tics
set key horizontal font "Helvetica, 20" width 1.8 at graph 0.84, graph 0.1 center maxrows 1
plot 0.5 title 'short' w l ls 4
unset multiplot

然而，这需要一些调整：

• 在第二个plot之前，您必须删除标题，标签，抽搐和边框，否则图表可能会因为不同的抗锯齿而呈锯齿状
• 要获得相同的页边距，您还必须设置固定的tmargin和bmargin
• 您必须手动定位密钥

上面的代码为您提供：

现在你必须判断它的价值。

Answer 2

您可以使用svg终端并通过在inkscape上打开svg文件进行调整。