Question

我有一系列地图，例如下面的coll。我想把它安排在一棵树上。每个映射都有一个名为：parent的键，它是父对象的id。关于我该怎么做的任何提示？

(def coll [{:id 1} 
          {:id 2 :parent 1} 
          {:id 3 :parent 1}
          {:id 4 :parent 2}
          {:id 5 :parent 4}
          {:id 6 :parent 5}
          {:id 7 :parent 5}
          {:id 8 :parent 5}
          {:id 9 :parent 7}])

Answer 1

如果它像树一样走......

(require '[clojure.zip :as z])

(defn create-zipper [s]
  (let [g (group-by :parent s)] 
    (z/zipper g #(map :id (g %)) nil (-> nil g first :id))))

(def t (create-zipper coll)) ; using the coll defined in the OP

(-> t z/root)
;=> 1

(-> t z/children)
;=> (2 3)

(-> t z/next z/children)
;=> (4)

请注意，您可以使用#(g (% :id))作为子项并使用(first (g nil))作为根目录来保留原始节点的格式（而不仅仅是返回ID号）。

如果需要，您可以使用post-order traversal构建树的另一个表示。

Answer 2

这是一个使用序列理解的小解决方案。希望它是可读的，但它肯定不会赢得任何性能奖励，因为它在每个递归级别重新过滤列表。我想有一个非常有效的基于降低的解决方案可能，但我仍然在写那些 - 希望其他人会发布一个:)。

注意 - 我已经为每个节点返回了整个地图，因为我不确定你想让你的树看起来像什么......

(defn make-tree
   ([coll] (let [root (first (remove :parent coll))]
               {:node root :children (make-tree root coll)}))
   ([root coll]
       (for [x coll :when (= (:parent x) (:id root))]
           {:node x :children (make-tree x coll)})))

(pprint (make-tree coll)) 

    {:node {:id 1},
     :children
       ({:node {:parent 1, :id 2},
         :children
           ({:node {:parent 2, :id 4},
             :children
               ({:node {:parent 4, :id 5},
                 :children
                   ({:node {:parent 5, :id 6}, :children ()} 
                    {:node {:parent 5, :id 7},
                     :children ({:node {:parent 7, :id 9}, :children ()})}
                    {:node {:parent 5, :id 8}, :children ()})})})}
    {:node {:parent 1, :id 3}, :children ()})}

如何将seq转换为树

2 个答案: