Question

我正在阅读LFS并遇到了野牛，我在其他地方之前看过它，所以我想我应该多了解一下。我发现this page from UC Riverside CS department并且示例代码无效。谁知道什么是错的？为方便起见，我粘贴了代码：

calc.lex 文件：

/* Mini Calculator */
/* calc.lex */

%{
#include "heading.h"
#include "tok.h"
int yyerror(char *s);
int yylineno = 1;
%}

digit       [0-9]
int_const   {digit}+

%%

{int_const} { yylval.int_val = atoi(yytext); return INTEGER_LITERAL; }
"+"     { yylval.op_val = new std::string(yytext); return PLUS; }
"*"     { yylval.op_val = new std::string(yytext); return MULT; }

[ \t]*      {}
[\n]        { yylineno++;   }

.       { std::cerr << "SCANNER "; yyerror(""); exit(1);    }

calc.y 档案：

/* Mini Calculator */
/* calc.y */

%{
#include "heading.h"
int yyerror(char *s);
int yylex(void);
%}

%union{
  int       int_val;
  string*   op_val;
}

%start  input 

%token  <int_val>   INTEGER_LITERAL
%type   <int_val>   exp
%left   PLUS
%left   MULT

%%

input:      /* empty */
        | exp   { cout << "Result: " << $1 << endl; }
        ;

exp:        INTEGER_LITERAL { $$ = $1; }
        | exp PLUS exp  { $$ = $1 + $3; }
        | exp MULT exp  { $$ = $1 * $3; }
        ;

%%

int yyerror(string s)
{
  extern int yylineno;  // defined and maintained in lex.c
  extern char *yytext;  // defined and maintained in lex.c

  cerr << "ERROR: " << s << " at symbol \"" << yytext;
  cerr << "\" on line " << yylineno << endl;
  exit(1);
}

int yyerror(char *s)
{
  return yyerror(string(s));
}

这是错误消息：

$ make
bison -d -v calc.y
cp calc.tab.c bison.c
cmp -s calc.tab.h tok.h || cp calc.tab.h tok.h
g++ -g -Wall -ansi -pedantic -c bison.c -o bison.o
calc.tab.c: In function ‘int yyparse()’:
calc.tab.c:1381: warning: deprecated conversion from string constant to ‘char*’
calc.tab.c:1524: warning: deprecated conversion from string constant to ‘char*’
flex calc.lex
cp lex.yy.c lex.c
g++ -g -Wall -ansi -pedantic -c lex.c -o lex.o
calc.lex:8: error: redefinition of ‘int yylineno’
lex.yy.c:349: error: ‘int yylineno’ previously defined here
calc.lex: In function ‘int yylex()’:
calc.lex:23: warning: deprecated conversion from string constant to ‘char*’
lex.yy.c: At global scope:
lex.yy.c:1105: warning: ‘void yyunput(int, char*)’ defined but not used
make: *** [lex.o] Error 1

Answer 1

问题是您正在使用C ++编译器编译C代码。如果你想要flex来生成C ++，那么就有一个命令行选项。

扫描程序生成的代码已经为yylineno提供了定义。

在C中，以下是可以接受的：

int yylineno;         /* tentative definition */
int yylineno = 1;     /* definition */

在C ++中，它不是：

int yylineno;         /* definition */
int yylineno = 1;     /* another definition: duplicate, error! */

另请注意，-ansi gcc选项适用于C语言。

关于字符串常量的警告也是因为C ++。在C ++中，像"abc"这样的字符串文字的计算结果为const char *，而不是char *。

最后，请注意，flex生成的扫描程序不会自动包含更新yylineno的代码。这是%option yylineno开启的。查看Flex上的GNU Info手册。

野牛示例代码不编译

1 个答案: