Question

我想将图片放在msgbox中。在我搜索它之后，我发现它是不可能的，所以我决定将图像放在msgbox上的输入框的背景中。但我找不到怎么做：

将图像作为输入框的背景
自定义输入框，如删除边框并更改背景颜色

Answer 1

内置InputBox功能不支持自定义背景。您可以使用Internet Explorer COM object构建自定义对话框：

Set ie = CreateObject("InternetExplorer.Application")

ie.Navigate "about:blank"
ie.document.title = "some title"
ie.ToolBar        = False
ie.Resizable      = False
ie.StatusBar      = False
ie.Width          = 300
ie.Height         = 150

Set style = ie.document.CreateStyleSheet()
style.AddRule "body", "background-image: url('C:\path\to\your.jpg')"
Set style = Nothing

Do Until ie.ReadyState = 4 : WScript.Sleep 100 : Loop

ie.document.body.innerHtml = "<p><input type='text' id='userinput'></p>" _
  & "<p><input type='hidden' id='OK' name='OK' value='0'>" _
  & "<input type='submit' value='OK' onClick='VBScript:OK.Value=1'>" _
  & "<input type='submit' value='Cancel' onClick='VBScript:OK.Value=-1'></p>"
ie.Visible = True
ie.document.all.userinput.focus

Do While ie.document.all.OK.value = 0 : WScript.Sleep 100 : Loop

If ie.document.all.OK.value = 1 Then
  'user pressed [OK]
Else
  'user clicked [Cancel]
End If

当然这只是一个非常基本的示例，因此您很可能需要进一步自定义样式以及HTML代码。一种可能的改进是以data URI：

的形式包含背景图像

style.AddRule "body", "background-image: url(data:image/jpeg;base64,/9j/4AA...')

这样您就不必为后台引用外部文件了。您可以使用免费的在线编码器将图像文件编码为base64，例如this one。

将图像作为输入框的背景

1 个答案: