Question

例如，

我的文件在 00.dat，01.dat，02.dat 之后命名...，每个文件包含多个列，我使用READCOL将它们读入变量。< / p>

for i = 0, n-1 do begin
    readcol, string(i, F='(I02)')+'.dat', F='D,D', a0, b0
    readcol, string(i, F='(I02)')+'.dat', F='D,D', a1, b1
    .
    .
    c1 = a1 / a0
    c2 = a2 / a0
    .
    .
    d1 = b1 / b0
    d2 = b2 / b0
    .
    .
endfor

这样可以正常工作，但如果有一百个变量，我不能逐个输入所有变量。

因此，我想使用for循环来生成： a（i），b（i），c（i），d（i）。从这个意义上说，代码看起来像：

for i = 0, n-1 do begin
    readcol, string(i, F='(I02)')+'.dat',F='D,D', a(i), b(i)
endfor

for i = 0, n-1 do begin
    c(i) = a(i) / a(0)
    d(i) = b(i) / b(0)
endfor

但这不起作用，是否有任何方法在for循环中声明变量并进行数学运算？

（我不是以英语为母语的人。如果我的问题中有任何不清楚的地方，请告诉我。谢谢！）

Answer 1

很高兴在StackOverflow上看到另一位IDL程序员！

我认为问题的一部分是READCOL期待简单的变量名称它的输出，在你的第二个例子中，你给它的数组表达式 a(i)和b(i)代替a和b。

如果我正确理解您的问题，您想要替换1维数组来自您的第一个示例的a0，a1，b0，b1等，包含二维数组a，b，其中每个数组都有维度（nfiles，samples_per_file）。所以如果你知道的话事先从每个文件中读取多少行，你可以这样做：

a=dblarr(n,samples_per_file)
b=dblarr(n,samples_per_file)
; similarly for c, d, etc.

for i = 0, n-1 do begin
    readcol, string(i, F='(I02)')+'.dat',F='D,D', x, y
    a[i,*] = x
    b[i,*] = y
    c[i,*] = x/x[0]
    d[i,*] = y/y[0]
endfor

此版本传递READCOL它期望的简单变量名称，然后复制它们进入二维变量的子阵列。

如果您事先不知道每个文件中有多少样本，则可以进行分配第一次循环迭代期间的二维数组：

for i = 0, n-1 do begin
    readcol, string(i, F='(I02)')+'.dat',F='D,D', x, y
    if (i EQ 0) then begin
       samples_per_file = n_elements(x)
       a = dblarr(n, samples_per_file)
       b = dblarr(n, samples_per_file)
       c = dblarr(n, samples_per_file)
       d = dblarr(n, samples_per_file)
    endif
    a[i,*] = x
    b[i,*] = y
    c[i,*] = x/x[0]
    d[i,*] = y/y[0]
endfor

当然，这一切都假定每个文件包含相同数量的样本。如果不，您可能需要将a，b，c和d更改为1维指针数组，然后在阅读时使用PTR_NEW为每个文件的数据分配内存。

（请注意，我使用方括号[]表示法进行数组索引，我找到了比a(i)，b(i)等更容易阅读，这可能与函数调用混淆。）

如何在for循环中声明变量？（IDL）

1 个答案:

如何在for循环中声明变量？ （IDL）

1 个答案:

如何在for循环中声明变量？（IDL）