Question

Access 2013不支持ADP。给出了ADP的一些替代方案：

将ADP转换为链接的Access桌面数据库。
将对象导入ACCDE文件，然后使用早期版本的Access创建现有数据的链接表。

我的ADP仅包含表单，报告，宏和模块。我想在Access 2013中使用此ADP（不在任何早期版本的Access上）。

我没有找到任何方法将ADP转换为链接的Access桌面数据库或将对象导入Access 2013上的ACCDE文件。

如何使用Access 2013将ADP转换为链接的Access桌面数据库或将对象导入ACCDE文件？

Answer 1

如何使用Access 2013将ADP转换为链接的Access桌面数据库或将对象导入ACCDE文件？

你做不到。 Access 2013无法与ADP文件完全一致。如果您尝试从Access 2013中的ADP文件导入对象，则会出现以下错误：

Access Data Projects are no longer supported in this version of Access.

您需要做的是

找到Access 2010或更早版本的计算机
使用它将查询，表单等从ADP导入.accdb或.mdb文件，然后
将.accdb或.mdb文件带回Access 2013计算机，然后从那里继续。

编辑重新评论

是否无法使用Access 2013
将ADP转换为链接的Access桌面数据库

显然不是。甚至尝试使用VBA将Form对象从.adp文件复制到.accdb文件失败。以下代码：

Option Compare Database
Option Explicit

Sub adpImportTest()
    Dim dbPath As String, formName As String
    On Error GoTo adpImportTest_Error

    Debug.Print "Try importing a form from an .accdb file..."
    dbPath = "C:\Users\Gord\Documents\accdbTest.accdb"
    formName = "myCustomers"
    DoCmd.TransferDatabase acImport, "Microsoft Access", dbPath, acForm, formName, formName
    Debug.Print "Import succeeded."

    Debug.Print
    Debug.Print "Try importing a form from an .adp file..."
    dbPath = "C:\Users\Gord\Documents\NorthwindCS.adp"
    formName = "Customers"
    DoCmd.TransferDatabase acImport, "Microsoft Access", dbPath, acForm, formName, formName
    Debug.Print "Import succeeded."

    Exit Sub
adpImportTest_Error:
    Debug.Print Err.Description
End Sub

...产生以下结果：

Try importing a form from an .accdb file...
Import succeeded.

Try importing a form from an .adp file...
The search key was not found in any record.

如果我们试图偷偷摸摸地将.adp文件重命名为.mdb，那么Access 2013将无法读取它：

Unrecognized database format

正如我所说，您需要使用Access 2010（或更早版本）将.adp文件中的对象提取到.accdb或.mdb文件中。然后您可以使用Access 2013中的.accdb或.mdb文件。

Answer 2

使用office＆lt; 2013 eg 2010 2007

尝试使用另存为文本/从文本加载来传输表单然后，您可以编辑为accdb链接表准备记录源的文本文件。

部分和未经清理的代码，但为您提供了一个想法

模块LoadSaveForm：

Option Compare Database
Option Base 0
Option Explicit

Dim path$
Dim DateTimeString$
Dim app As Access.Application



Function SaveFormAsText(FormName As String) As Boolean
  Dim sPath As String
  Access.SaveAsText acForm, FormName, "C:\Temp" & "\" & FormName & ".txt"
End Function

Function LoadFormFromText(FormName As String)
  Access.LoadFromText acForm, FormName, "C:\Temp" & "\" & FormName & ".txt"
End Function

Private Sub SaveMDBObjectsAsText()

    DateTimeString = Format(Now(), "yyyymmddhhnn")
    path = CurrentProject.path & "\" '& "AS_TEXT_" & DateTimeString & "\"

    If Dir(path) <> "" Then
        'It exists
    Else
        On Error Resume Next
        MkDir path
        On Error GoTo 0

    End If

    SaveDataAccessPagesAsText
    SaveFormsAsText
    SaveReportsAsText
    SaveModulesAsText
    'SaveQueriesAsText
    CreateProjectFromText (path)

End Sub


Public Sub CreateProjectFromText(pathString As String)
    path = pathString
    'SaveMDBBase
    SaveAccdbDBase
    LoadDataAccessPagesFromText
    LoadFormsFromText
    LoadReportsFromText
    LoadModulesFromText
    'LoadQueriesFromText
    On Error Resume Next
    Dim r As Reference
    With app
        With .CurrentProject
            path = .FullName
        End With

        For Each r In .References
            With r
                If Not .BuiltIn Then
                    app.References.Remove r
                End If
            End With
        Next r

        For Each r In References
            With r
                If Not .BuiltIn Then
                    app.References.AddFromGuid r.GUID, r.Major, r.Minor
                End If
            End With
        Next r
        .RunCommand acCmdSaveAllModules
        .RunCommand acCmdCompileAndSaveAllModules
        .CloseCurrentDatabase
        .SysCmd 603, path, Replace(Replace(Replace(path, ".accdb", ".accde"), ".adp", ".ade"), ".mdb", ".mde")
        .Quit
    End With
    Set app = Nothing
    MsgBox "All Done with Text Backup"

End Sub

Private Sub SaveDataAccessPagesAsText()
    Dim filename$
    Dim Name$
    Dim DataAccessPage As AccessObject
    For Each DataAccessPage In CurrentProject.AllDataAccessPages
        Name = DataAccessPage.Name
        filename = path & Name & ".txt"
        SaveAsText acDataAccessPage, Name, filename
    Next DataAccessPage
End Sub

Private Sub SaveFormsAsText()
    Dim filename$
    Dim Name$
    Dim Form As AccessObject
    For Each Form In CurrentProject.AllForms
        Name = Form.Name
        filename = path & Name & ".txt"
        SaveAsText acForm, Name, filename
    Next Form
End Sub

Private Sub SaveReportsAsText()
    Dim filename$
    Dim Name$
    Dim Report As AccessObject
    For Each Report In CurrentProject.AllReports
        Name = Report.Name
        filename = path & Name & ".txt"
        SaveAsText acReport, Name, filename
    Next Report
End Sub

Private Sub SaveMacrosAsText()
    Dim filename$
    Dim Name$
    Dim Macro As AccessObject
    For Each Macro In CurrentProject.AllMacros
        Name = Macro.Name
        filename = path & Name & ".txt"
        SaveAsText acMacro, Name, filename
    Next Macro
End Sub

Private Sub SaveModulesAsText()
    Dim filename$
    Dim Name$
    Dim Module As AccessObject
    For Each Module In CurrentProject.AllModules
        Name = Module.Name
        filename = path & Name & ".txt"
        SaveAsText acModule, Name, filename
    Next Module
End Sub

Private Sub SaveQueriesAsText()
    Dim filename$
    Dim Name$
    Dim GetQueryNames As ADODB.Recordset
    Set GetQueryNames = CurrentProject.connection.OpenSchema(adSchemaViews)
    With GetQueryNames
        Do While Not .EOF
            Name = .Fields("TABLE_NAME")
            filename = path & Name & ".txt"
            SaveAsText acQuery, Name, filename
            .MoveNext
        Loop
    End With
End Sub

Private Function SaveAccdbDBase() As Database
    Dim ws As DAO.Workspace
    Dim db As DAO.Database

    'Get default Workspace
    Set ws = DBEngine.Workspaces(0)

    Dim filename$
    Dim Name$
    Name = Replace(CurrentProject.Name, CurrentProject.path, "")
    If Name Like "*.adp" Then
        Name = Replace(Name, "adp", "accdb")
    Else
        Name = Replace(Name, "accdb", "adp")
  End If
    filename = path & Name
 'Make sure there isn't already a file with the name of the new database
   If Dir(filename) <> "" Then Kill filename

   Set app = CreateObject("Access.Application")
   'Create a new mdb file
   If Name Like "*.adp" Then
        Application.CreateAccessProject filename, getConnection.ConnectionString
    Else
    Set db = ws.CreateDatabase(filename, dbLangGeneral)
    End If
   db.Close
   Set db = Nothing
    'SaveAsText 6, "", filename
    If Name Like "*.adp" Then

        app.Visible = True
        app.UserControl = True
        app.OpenAccessProject filename
    Else
        app.OpenCurrentDatabase filename
    End If
    app.SetOption "Show Navigation Pane Search Bar", True
    Set SaveAccdbDBase = db
End Function

Private Sub LoadDataAccessPagesFromText()
    Dim filename$
    Dim Name$
    Dim DataAccessPage As AccessObject
    For Each DataAccessPage In CurrentProject.AllDataAccessPages
        Name = DataAccessPage.Name
        filename = path & Name & ".txt"
        app.LoadFromText acDataAccessPage, Name, filename
    Next DataAccessPage
End Sub

Private Sub LoadFormsFromText()
    Dim filename$
    Dim Name$
    Dim Form As AccessObject
    For Each Form In CurrentProject.AllForms
        Name = Form.Name
        filename = path & Name & ".txt"
        On Error Resume Next
        app.LoadFromText acForm, Name, filename
    Next Form
End Sub

Sub CreateNewMDBFile()

   Dim ws As Workspace
   Dim db As Database
   Dim LFilename As String

   'Get default Workspace
   Set ws = DBEngine.Workspaces(0)

   'Path and file name for new mdb file
   LFilename = "c:\NewDB.mdb"

   'Make sure there isn't already a file with the name of the new database
   If Dir(LFilename) <> "" Then Kill LFilename

   'Create a new mdb file
   Set db = ws.CreateDatabase(LFilename, dbLangGeneral)

   'For lookup tables, export both table definition and data to new mdb file
   DoCmd.TransferDatabase acExport, "Microsoft Access", LFilename, acTable, "Lookup Table1", "Lookup Table1", False

   'For data entry tables, export only table definition to new mdb file
   DoCmd.TransferDatabase acExport, "Microsoft Access", LFilename, acTable, "DataEntry Table1", "DataEntry Table1", True

   db.Close
   Set db = Nothing

End Sub

运行SaveMDBObjectsAsText（）以了解发生的事情

如何使用Access 2013将ADP转换为ACCDB？

2 个答案: