PerlTk标签 - 同一小部件​​中的不同颜色文本

Question

我编写了一个与我们的psql数据库交互的GUI。对于给定日期，gui显示具有各种标识符和信息位的人员列表。我使用Tk :: Table来显示数据

eg
my $f_mainframe = $mw -> Frame(-bg=>'white');
$f_mainframe -> pack(-side=>'top', -expand=>1, -fill=>'both');
my $itable = $f_mainframe -> Table(-rows => 13,
                   -columns=>30,
                   -fixedrows => 1,
                   -fixedcolumns => 1,
                   -relief => 'raised') -> pack();

$itable->put(1,$firstnamecol,"First Name\nMYO");

是否可以将黑色的“名字”和红色的“MYO”着色？

Answer 1

通过在带有字符串参数的->put上使用Tk::Table方法，可以创建一个简单的Tk::Label小部件。标签只能配置为具有单个前景色。要实现您的目标，您可以使用Tk::ROText（只读文本小部件）。以下代码显示标签小部件和文本小部件，但后者具有不同的颜色：

use strict;
use Tk;
use Tk::ROText;

my $mw = tkinit;

# The monocolored Label variant
my $l = $mw->Label
    (
     -text => "First Name\nMYO",
     -font => "{sans serif} 12",
    )->pack;

# The multicolored ROText variant
my $txt = $mw->ROText
    (
     -borderwidth => 0, -highlightthickness => 0, # remove extra borders
     -takefocus => 0, # make widget unfocusable
     -font => "{sans serif} 12",
    )->pack;
$txt->tagConfigure
    (
     'blue',
     -foreground => "blue",
     -justify => 'center', # to get same behavior as with Tk::Label
    );
$txt->tagConfigure
    (
     'red',
     -foreground => "red",
     -justify => 'center', # to get same behavior as with Tk::Label
    );
$txt->insert("end", "First Name\n", "blue", "MYO", "red");
# a hack to make the ROText geometry the same as the Label geometry
$txt->GeometryRequest($l->reqwidth, $l->reqheight);

MainLoop;

如您所见，使文本小部件变体工作的输入更多。因此，将此代码抽象为子例程或窗口小部件类（可能是CPAN的东西）可能很有用。另请注意，您必须自己处理文本小部件的几何。标签自动延伸以容纳标签内容。默认情况下，文本窗口小部件的几何体为80x24个字符，并且不会根据其内容自动收缩或扩展。在示例中，我使用GeometryRequest的hack来强制使用与等效标签窗口小部件相同的几何体。也许您可以使用-width和-height进行硬编码。另一种解决方案可能是使用bbox() / Tk::Text的{​​{1}}方法来计算几何。