Question

我编写了简单的第一阶段bootloader，它使用对bios的中断显示“Hello world”。现在作为编写第二阶段的下一个明显步骤，但是应该存在代码以及如何从第一阶段加载它？

这是第一阶段的程序

[BITS 16]   ;Tells the assembler that its a 16 bit code
[ORG 0x7C00]    ;Origin, tell the assembler that where the code will
                ;be in memory after it is been loaded

MOV SI, HelloString ;Store string pointer to SI
CALL PrintString    ;Call print string procedure
JMP $       ;Infinite loop, hang it here.


PrintCharacter: ;Procedure to print character on screen
    ;Assume that ASCII value is in register AL
MOV AH, 0x0E    ;Tell BIOS that we need to print one charater on screen.
MOV BH, 0x00    ;Page no.
MOV BL, 0x07    ;Text attribute 0x07 is lightgrey font on black background

INT 0x10    ;Call video interrupt
RET     ;Return to calling procedure



PrintString:    ;Procedure to print string on screen
    ;Assume that string starting pointer is in register SI

next_character: ;Lable to fetch next character from string
MOV AL, [SI]    ;Get a byte from string and store in AL register
INC SI      ;Increment SI pointer
OR AL, AL   ;Check if value in AL is zero (end of string)
JZ exit_function ;If end then return
CALL PrintCharacter ;Else print the character which is in AL register
JMP next_character  ;Fetch next character from string
exit_function:  ;End label
RET     ;Return from procedure


;Data
HelloString db 'Hello World', 0 ;HelloWorld string ending with 0

TIMES 510 - ($ - $$) db 0   ;Fill the rest of sector with 0
DW 0xAA55           ;Add boot signature at the end of bootloader

Answer 1

在x86上，您将执行以下操作（简化）：

让引导加载程序将磁盘/软盘的第n个扇区（无论您从哪里启动）加载到内存中并执行它（即加载段/偏移并执行retf）。更好的选择是在文件系统中搜索某个文件名（例如KERNEL.BIN） - 但是您需要知道文件系统类型（例如，如果您正在从软盘映像进行测试，则为FAT12）。
然后内核将以实模式启动。它设置代码描述符，GDT等，激活32位寻址（你应该听说过“A20”），最后进入保护模式。然后你需要远程跳转到32位代码段（内核文件必须以32位代码处于绝对位置的方式链接在一起，例如在偏移512处，在16位实模式之后）
然后，32位内核程序集只定义EXTERN _mykernel（例如）并调用该符号。
然后您就可以开始将内核编写为C函数mykernel。

好的，这是我几年前做过的简短概述（有很多来自互联网的复制和粘贴;）。如果这没有帮助，这里有一些关于OS开发的好的Web资源：

http://www.brokenthorn.com/Resources/OSDevIndex.html
http://wiki.osdev.org/Main_Page
http://lowlevel.brainsware.org/wiki/index.php/Hauptseite（wiki与许多业余爱好者OS开发人员，仅限德语......）

希望有所帮助^^

Answer 2

加载第2阶段并跳转到第2阶段的最小可运行NASM BIOS示例

use16
org 0x7C00

    ; You should do further initializations here
    ; like setup the stack and segment registers.

    ; Load stage 2 to memory.
    mov ah, 0x02
    ; Number of sectors to read.
    mov al, 1
    ; This may not be necessary as many BIOS set it up as an initial state.
    mov dl, 0x80
    ; Cylinder number.
    mov ch, 0
    ; Head number.
    mov dh, 0
    ; Starting sector number. 2 because 1 was already loaded.
    mov cl, 2
    ; Where to load to.
    mov bx, stage2
    int 0x13

    jmp stage2

    ; Magic bytes.    
    times ((0x200 - 2) - ($ - $$)) db 0x00
    dw 0xAA55

stage2:

    ; Print 'a'.
    mov ax, 0x0E61
    int 0x10

    cli
    hlt

    ; Pad image to multiple of 512 bytes.
    times ((0x400) - ($ - $$)) db 0x00

编译并运行：

nasm -f bin -o main.img main.asm
qemu-system-i386 main.img

预期结果：a被打印到屏幕上，然后程序停止。

在Ubuntu 14.04上测试。

Saner GAS示例使用链接描述文件和更正确的初始化（段寄存器，堆栈）on my GitHub。

Answer 3

在这里查看GRUB实现（第1阶段）：

http://src.illumos.org/source/xref/illumos-gate/usr/src/grub/grub-0.97/stage1/stage1.S

首先注意到第一个扇区的起始点为0x7c00，结束签名为0xaa55。从反汇编中，你可以看到：

349 copy_buffer:
350   movw    ABS(stage2_segment), %es
351 
352   /*
353    * We need to save %cx and %si because the startup code in
354    * stage2 uses them without initializing them.
355    */
356   pusha
357   pushw   %ds
358 
359   movw    $0x100, %cx
360   movw    %bx, %ds
361   xorw    %si, %si
362   xorw    %di, %di
363 
364   cld
365 
366   rep
367   movsw
368 
369   popw    %ds
370   popa
371 
372   /* boot stage2 */
373   jmp *(stage2_address)
374 
375 /* END OF MAIN LOOP */
376

本质上，逻辑是将第2阶段代码复制到内存的另一部分，然后直接跳转到那里，那就是“引导阶段2”。换句话说，“boot stage1”在将扇区加载到内存后从BIOS有效触发，而stage2则是你跳到那里的地方 - 它可以在任何地方。

如何从第一阶段加载第二阶段启动加载程序？

3 个答案: