VBA（Excel）：基于多个搜索标准查找而不循环

Question

我有一个大型数据表，我想根据3套标准在VBA中搜索。可以假设每个行条目是唯一的。由于要求，无法更改工作表/数据本身的格式。 （我在相关问题上看过几篇帖子，但尚未找到有效的解决方案。）

起初我在循环中使用了经典的VBA find方法：

Set foundItem = itemRange.Find(What:=itemName, Lookin:=xlValues, lookat:=xlWhole, SearchOrder:=xlByRows)
If Not foundItem Is Nothing Then
    firstMatchAddr = foundItem.Address
    Do
        ' *Check the other fields in this row for a match and exit if found*
        Set foundItem = itemRange.FindNext(foundItem)
    Loop While foundItem.Address <> firstMatchAddr  And Not foundItem Is Nothing
End If

但是因为需要在大型数据集上多次调用，所以速度并不好。

我进行了一些搜索，发现我可以将match方法与index一起使用。所以我没有成功尝试过很多变种，例如：

result = Evaluate("=MATCH(1, (""" & criteria1Name & """=A2:A" & lastRow & ")*(""" & criteria2Name & """=B2:B" & lastRow & ")*(""" & criteria3Name & """=C2:C" & lastRow & "), 0)")

和

result = Application.WorksheetFunction.Index(resultRange, Application.WorksheetFunction.Match((criteria1Name = criteria1Range)*(criteria2Name = criteria2Range)*(criteria3Name = criteria3Range))

和

result = Application.WorksheetFunction.Index(resultRange, Application.WorksheetFunction.Match((criteria1Range=criteria1Name )*(criteria2Range=criteria2Name )*(criteria3Range=criteria3Name ))

然后我尝试使用AutoFilter进行排序：

.Range(.Cells(1,1), .Cells(lastRow, lastCol)).AutoFilter Field:=1, Criteria1:="=" & criteria1Name
.Range(.Cells(1,1), .Cells(lastRow, lastCol)).AutoFilter Field:=2, Criteria1:="=" & criteria2Name
.Range(.Cells(1,1), .Cells(lastRow, lastCol)).AutoFilter Field:=3, Criteria1:="=" & criteria3Name

但是由于其中一个排序列包含日期，因此我遇到了使AutoFilter正常工作的问题。

我的问题是，如何根据多个条件搜索Excel VBA中的列，不循环，返回行号或该行单元格中的值我对感兴趣？

Answer 1

您可以使用高级过滤器。将列标题放在工作表的单独部分（或完全不同的工作表）。在这些列标题下，将您要查找的条件放在每列中。然后将该范围（包括标题）命名为“Criteria”。然后宏变成：

Sub Macro1()

    Sheets("Sheet1").Range("A1").CurrentRegion.AdvancedFilter xlFilterInPlace, Range("Criteria")

End Sub

作为以下评论的后续内容，让VBA在幕后创建标准范围：

Sub Macro1()

    'Code up here that defines the criteria

    Application.ScreenUpdating = False
    Application.DisplayAlerts = False

    With Sheets.Add
        'Create the advanced filter criteria range
        .Range("A1") = "HeaderA"
        .Range("B1") = "HeaderB"
        .Range("C1") = "HeaderC"
        .Range("A2") = criteria1Name
        .Range("B2") = criteria2Name
        .Range("C2") = criteria3Name

        'Alternately, to save space:
        '.Range("A1:C1").Value = Array("HeaderA", "HeaderB", "HeaderC")
        '.Range("A2:C2").Value = Array(criteria1Name, criteria2Name, criteria3Name)

        'Then perform the advanced filter
        Sheets("Sheet1").Range("A1").CurrentRegion.AdvancedFilter xlFilterInPlace, .Range("A1:C2")

        'Remove behind the scenes sheet now that the filter is completed
        .Delete
    End With

    Application.ScreenUpdating = True
    Application.DisplayAlerts = True

End Sub

Answer 2

您可以将EVALUATE用于多个条件，例如返回计算值的行号。这使用与Is it possible to fill an array with row numbers which match a certain criteria without looping?

相同的方法

• 搜索50000行以匹配
  • A列中的前四个字母与fred
  相匹配
  • B中的日期大于1/1/2001
  第5栏
  • apple
• 符合这些条件的所有行都会在x
中重新调整为行号

（下图中的第1行和第5行）

代码

Sub GetEm2()
x = Filter(Application.Transpose(Application.Evaluate("=IF((LEFT(A1:A10000,4)=""fred"")*(B1:B10000>date(2001,1,1))*(C1:C10000=""apple""),ROW(A1:A10000),""x"")")), "x", False)
End Sub

Application.Transpose限制为65536个单元格，因此较长的范围需要“分块”成碎片。