好的我正在尝试使用Mallet对Windows中的某些文档进行分类
我在Linux中实现了它。只是无法让它在Windows(目标环境)中完成工作
我已将数据导入.mallet文件。
然后使用此输入数据创建分类器。
-rw-r--r-- 1 henry henry 15197116 Feb 23 15:56 nntp.classifier
和
07/03/2014 21:28 15,197,116 nntp.classifier
然而,当我在Linux中运行时:
bin / mallet classify-dir --input ./testfolder --output - --classifier nntp.classifier
它会迭代testfolder中的所有文件并转出它认为的每个类。
但是如果我在Windows中运行相同的命令:
bin\mallet classify-dir --input ./testfolder --output - --classifier nntp.classifier
它只是转出命令列表:
Mallet 2.0 commands:
import-dir load the contents of a directory into mallet instances (one per file)
import-file load a single file into mallet instances (one per line)
import-svmlight load a single SVMLight format data file into mallet instances (one per line)
train-classifier train a classifier from Mallet data files
train-topics train a topic model from Mallet data files
infer-topics use a trained topic model to infer topics for new documents
estimate-topics estimate the probability of new documents given a trained model
hlda train a topic model using Hierarchical LDA
prune remove features based on frequency or information gain
split divide data into testing, training, and validation portions
Include --help with any option for more information
我注意到的事情:我
f我在linux中运行bin/mallet classify-dir --help
我得到了帮助文件,即每个命令的描述,但Windows bin\mallet classify-dir --help
中的相同内容不会产生相同的结果 - 只是上面的命令列表... (如果你输入垃圾作为命令它会做同样的事情)
而早先的命令之一,例如bin/mallet import-dir --help
和bin\mallet import-dir --help
生成相同的完整帮助文件输出。
答案 0 :(得分:2)
请注意,ignazio提供的.bat文件的第23行有一个拼写错误(并且很遗憾地包含在mallet-2.0.7下载中)导致它查找“import-smvlight”而不是“import” -svmlight“,这是帮助信息中指定的内容。如果要使用此功能,请确保切换“m”和“v”。
答案 1 :(得分:1)
bin目录中的whit mallet.bat文件存在问题。 你应该在:
修改它@echo off
rem This batch file serves as a wrapper for several
rem MALLET command line tools.
if not "%MALLET_HOME%" == "" goto gotMalletHome
echo MALLET requires an environment variable MALLET_HOME.
goto :eof
:gotMalletHome
set MALLET_CLASSPATH=%MALLET_HOME%\class;%MALLET_HOME%\lib\mallet-deps.jar
set MALLET_MEMORY=1G
set MALLET_ENCODING=UTF-8
set CMD=%1
shift
set CLASS=
if "%CMD%"=="import-dir" set CLASS=cc.mallet.classify.tui.Text2Vectors
if "%CMD%"=="import-file" set CLASS=cc.mallet.classify.tui.Csv2Vectors
if "%CMD%"=="import-smvlight" set CLASS=cc.mallet.classify.tui.SvmLight2Vectors
if "%CMD%"=="train-classifier" set CLASS=cc.mallet.classify.tui.Vectors2Classify
if "%CMD%"=="classify-dir" set CLASS=cc.mallet.classify.tui.Text2Classify
if "%CMD%"=="classify-file" set CLASS=cc.mallet.classify.tui.Csv2Classify
if "%CMD%"=="train-topics" set CLASS=cc.mallet.topics.tui.Vectors2Topics
if "%CMD%"=="infer-topics" set CLASS=cc.mallet.topics.tui.InferTopics
if "%CMD%"=="estimate-topics" set CLASS=cc.mallet.topics.tui.EvaluateTopics
if "%CMD%"=="hlda" set CLASS=cc.mallet.topics.tui.HierarchicalLDATUI
if "%CMD%"=="prune" set CLASS=cc.mallet.classify.tui.Vectors2Vectors
if "%CMD%"=="split" set CLASS=cc.mallet.classify.tui.Vectors2Vectors
if "%CMD%"=="bulk-load" set CLASS=cc.mallet.util.BulkLoader
if "%CMD%"=="run" set CLASS=%1 & shift
if not "%CLASS%" == "" goto gotClass
echo Mallet 2.0 commands:
echo import-dir load the contents of a directory into mallet instances (one per file)
echo import-file load a single file into mallet instances (one per line)
echo import-svmlight load a single SVMLight format data file into mallet instances (one per line)
echo train-classifier train a classifier from Mallet data files
echo classify-dir classify the contents of a directory with a saved classifier
echo classify-file classify a file with a saved classifier
echo train-topics train a topic model from Mallet data files
echo infer-topics use a trained topic model to infer topics for new documents
echo estimate-topics estimate the probability of new documents given a trained model
echo hlda train a topic model using Hierarchical LDA
echo prune remove features based on frequency or information gain
echo split divide data into testing, training, and validation portions
echo Include --help with any option for more information
goto :eof
:gotClass
set MALLET_ARGS=
:getArg
if "%1"=="" goto run
set MALLET_ARGS=%MALLET_ARGS% %1
shift
goto getArg
:run
java -Xmx%MALLET_MEMORY% -ea -Dfile.encoding=%MALLET_ENCODING% -classpath %MALLET_CLASSPATH% %CLASS% %MALLET_ARGS%
:eof
能够在Windows环境中进行分类。
我希望这可以提供帮助。
纳齐奥西隆