Question

我有一个链接到许多共享库的项目。

让我们说项目A取决于项目B和C

理想情况下，我想在我的项目文件中强加以下依赖项：

如果自上次构建项目A后重建了B或C，则重建项目A
将输出用于相关配置（即，如果在调试模式下构建项目A，则使用项目B和C的库的调试版本）

有谁知道我如何在我的项目文件中明确表达这种依赖？

Answer 1

在对qmake感到非常沮丧之后，我发现了我认为你问题的答案。如果没有，那么我已经学会了使用qmake的方式，直到找到更好的东西，因为这仍然有点难看。我设置了一个演示项目，这是我的目录结构（文件有扩展名，文件夹没有）：

MyProj
    MyProj.pro
    myproj-core
        myproj-core.pro
        globals.h
        MyProjCore.h
        MyProjCore.cpp
    myproj-app
        myproj-app.pro
        main.cpp

我们从MyProj.pro作为subdirs项目开始，这是做您要求的关键。基本上，您只需将其设置在一个qmake文件上，而不是依赖于其他项目来指定调试/发布和各种其他垃圾。它不会让你只做你需要的东西，但它是我能想到的最好的解决方案。以下是内容：

TEMPLATE = subdirs
# Needed to ensure that things are built right, which you have to do yourself :(
CONFIG += ordered

# All the projects in your application are sub-projects of your solution
SUBDIRS = myproj-core \
          myproj-app

# Use .depends to specify that a project depends on another.
myproj-app.depends = myproj-core

myproj-core.pro是您典型的共享对象库：

QT -= gui
TARGET = myproj-core
TEMPLATE = lib
DEFINES += MYPROJCORE_LIBRARY
SOURCES += MyProjCore.cpp
HEADERS += MyProjCore.h \
           globals.h

myproj-app.pro是消费者应用程序，其中需要重建的小技巧是：

QT       -= gui

TARGET = myproj-app
CONFIG   += console
CONFIG   -= app_bundle

TEMPLATE = app

# Specify that we're lookin in myproj-core.  Realistically, this should be put
# in some configuration file
INCLUDEPATH += ../myproj-core
# Link to the library generated by the project.  Could use variables or
# something here to make it more bulletproof
LIBS += ../myproj-core/libmyproj-core.so
# Specify that we depend on the library (which, logically would be implicit from
# the fact that we are linking to it)
PRE_TARGETDEPS += ../myproj-core/libmyproj-core.so

SOURCES += main.cpp

我希望这能解决你的问题，因为我知道这解决了我的问题！

编辑：我专门为我构建了一个依赖项文件，我将它存储在我的每个项目的兄弟文件夹中（上面指定的目录结构中MyProj的子项），名为{ {1}}：

dependencies.pri

所以在所有消费应用程序的底部，我可以添加以下行：

# On windows, a shared object is a .dll
win32: SONAME=dll
else:  SONAME=so

# This function sets up the dependencies for libraries that are built with
# this project.  Specify the libraries you need to depend on in the variable
# DEPENDENCY_LIBRARIES and this will add
for(dep, DEPENDENCY_LIBRARIES) {
    #message($$TARGET depends on $$dep ($${DESTDIR}/$${dep}.$${SONAME}))
    LIBS += $${DESTDIR}/lib$${dep}.$${SONAME}
    PRE_TARGETDEPS += $${DESTDIR}/lib$${dep}.$${SONAME}
}

这假设您正在将库复制到某个共享位置和/或根据需要移动它们，因此我的功能可能对您不起作用，但我想我会将其添加到解决方案中。

Answer 2

我使用下面的解决方案。这可以在不使用带有子模板的额外.pro文件的情况下工作。

TEMPLATE = app
TARGET = MyApp
PRE_TARGETDEPS = ../../libs/MyLib/MyLib.a
INCLUDEPATH += ../../libs/MyLib/include 
HEADERS += src/MyApp.h \
    ../../libs/MyLib/incude/MyLib.h
SOURCES += src/MyApp.cpp
LIBS += ../../libs/MyLib/MyLib.a

MyLib.target = ../../libs/MyLib/MyLib.a
MyLib.commands = cd ../../libs/MyLib && make
MyLib.depends = ../../libs/MyLib/Makefile
QMAKE_EXTRA_TARGETS += MyLib

Answer 3

查看此问题：Force relink when building in QT Creator

尝试在您的专业文件中添加与此代码类似的内容：

CONFIG(debug, debug|release) {   
    DESTDIR = ../../../bin/debug  
    OBJECTS_DIR = ./debug  
}  
else {   
    DESTDIR = ../../../bin/release  
    OBJECTS_DIR = ./release  
}

然后，您必须为每个配置指定依赖项：

CONFIG(debug, debug|release) {   
    LIBS += -L../../../lib/debug \  
        -L../../../bin/debug \  
        -llib1 \  
        -llib2   
    PRE_TARGETDEPS += ../../../lib/debug/liblib1.a \  
        ../../../lib/debug/liblib2.a 
else { 
    LIBS += -L../../../lib/release \
        -L../../../bin/release \
        -llib1 \  
        -llib2   
    PRE_TARGETDEPS += ../../../lib/release/liblib1.a \
        ../../../lib/release/liblib2.a 
}

Answer 4

我在重构我的项目后遇到了这个问题，之后我在一个新的DLL（pqXDot）中移动了一个可重用的类（来自pqGraphviz）。

在我的项目中添加一个新的DLL，并将新的DLL引用添加到其他需要它的DLL和应用程序后，我在主.pro：

TEMPLATE = subdirs

SUBDIRS += \
    pqConsole \
    pqConsoleTest \
    pqSource \
    pqSourceTest \
    fdqueens \
    pqGraphviz \
    pqGraphvizTest \
    pqXDot

并且重建导致链接器错误，因为正在重构的DLL pqGraphviz找不到新的DLL pqXDot。

事实证明，重新排序SUBDIRS列表就足够了，在所依赖的列表之前移动所需的DLL：

SUBDIRS += \
    pqConsole \
    pqConsoleTest \
    pqSource \
    pqSourceTest \
    fdqueens \
    pqXDot \
    pqGraphviz \
    pqGraphvizTest

Answer 5

对于那些对Qt / QML项目模板感兴趣的人，我在GitHub上发布了一个模板QmlAppTemplate。

Qmake项目依赖项（链接库）

5 个答案: