Question

有没有办法可以在Perl脚本中当前位置之前访问（打印输出）子+模块列表到任意深度的子调用？

我需要更改一些Perl模块（.pm）。工作流通过cgi脚本从网页启动，通过在我需要使用数据的模块中结束的几个模块/对象传递输入。在某个地方，数据发生了变化，我需要找出原因。

Answer 1

您可以使用Devel::StackTrace。

use Devel::StackTrace;
my $trace = Devel::StackTrace->new;
print $trace->as_string; # like carp

它的行为类似于Carp的踪迹，但您可以更好地控制帧。

一个问题是引用是字符串化的，如果引用的值发生变化，您将看不到它。但是，您可以使用PadWalker打开一些内容来打印出完整的数据（但这会很大）。

Answer 2

caller可以做到这一点，尽管您可能需要更多信息。

Answer 3

Carp::longmess会做你想要的，而且是标准的。

use Carp qw<longmess>;
use Data::Dumper;
sub A { &B; }
sub B { &C; }
sub C { &D; }
sub D { &E; }

sub E { 
    # Uncomment below if you want to see the place in E
    # local $Carp::CarpLevel = -1; 
    my $mess = longmess();
    print Dumper( $mess );
}

A();
__END__
$VAR1 = ' at - line 14
    main::D called at - line 12
    main::C called at - line 10
    main::B called at - line 8
    main::A() called at - line 23
';

我想出了这个子（现在有可选的祝福'动作！）

my $stack_frame_re = qr{
    ^                # Beginning of line
    \s*              # Any number of spaces
    ( [\w:]+ )       # Package + sub
    (?: [(] ( .*? ) [)] )? # Anything between two parens
    \s+              # At least one space
    called [ ] at    # "called" followed by a single space
    \s+ ( \S+ ) \s+  # Spaces surrounding at least one non-space character
    line [ ] (\d+)   # line designation
}x;

sub get_stack {
    my @lines = split /\s*\n\s*/, longmess;
    shift @lines;
    my @frames
        = map { 
              my ( $sub_name, $arg_str, $file, $line ) = /$stack_frame_re/;
              my $ref =  { sub_name => $sub_name
                         , args     => [ map { s/^'//; s/'$//; $_ } 
                                         split /\s*,\s*/, $arg_str 
                                       ]
                         , file     => $file
                         , line     => $line 
                         };
              bless $ref, $_[0] if @_;
              $ref
          } 
          @lines
       ;
    return wantarray ? @frames : \@frames;
}

Answer 4

还有Carp::confess和Carp::cluck。

Answer 5

此代码无需任何其他模块。只需将它包含在需要的地方。

my $i = 1;
print STDERR "Stack Trace:\n";
while ( (my @call_details = (caller($i++))) ){
    print STDERR $call_details[1].":".$call_details[2]." in function ".$call_details[3]."\n";
}

Answer 6

更漂亮的一个：Devel::PrettyTrace

use Devel::PrettyTrace;
bt;

Answer 7

万一您不能使用（或想避免使用）非核心模块，这是我想到的一个简单子程序：

#!/usr/bin/perl
use strict;
use warnings;

sub printstack {
    my ($package, $filename, $line, $subroutine, $hasargs, $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash);
    my $i = 1;
    my @r;
    while (@r = caller($i)) {
        ($package, $filename, $line, $subroutine, $hasargs, $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash) = @r;
        print "$filename:$line $subroutine\n";
        $i++;
    }
}

sub i {
    printstack();
}

sub h {
    i;
}

sub g {
    h;
}

g;

它产生如下输出：

/root/_/1.pl:21 main::i
/root/_/1.pl:25 main::h
/root/_/1.pl:28 main::g

或者一个班轮：

for (my $i = 0; my @r = caller($i); $i++) { print "$r[1]:$r[2] $r[3]\n"; }

您可以在呼叫方here上找到文档。

Answer 8

将my comment移至答案：

安装Devel::Confess right way
```
cpanm Devel::Confess
```
运行方式
```
perl -d:Confess myscript.pl
```

出现错误时，将显示整个调用堆栈列表。

如何在Perl中获得调用堆栈列表？

8 个答案: