Question

我经常想把两个变量的乘积表制成表格。例如，假设我有x1和x2，两者都是整数值。在R中，table(x1 * x2)做我想要的。我不需要创建一个新变量（比如x3）来获取我需要的信息。

我想在Stata做同样的事情。也就是说，我想运行像tabulate x1*x2这样的命令。（我需要一直这样做，这是我不想首先创建新变量x3的一个原因。）有没有办法在Stata中做到这一点？

Answer 1

如果没有一些编程工作，我认为你不会得到这种行为。请注意，tabulate需要 varnames 或 varlists ，并且不允许使用表达式。见help tabulate。当然，generate是一个允许表达式的命令。有关详细信息，请参阅help exp。

我记得在Statalist中按照“即时计算”的方式进行了讨论，但我现在无法找到它;您可能想查看archives。如果我没记错的话，除了因子变量之外的其他因素，你可以使用因子变量符号（help factor variables）“动态”使用。我记得有充分的理由说明为什么会这样。

但是对于类似两个变量的产品，您可以在.ado文件中编写一个简单的程序，将其保存在Stata系统目录（最好是〜/ ado / personal /）中，然后随时使用它。

以下是一个示例程序：

program define tabulate2, byable(recall)

    /* 
    Tabulate the product of two variables.
    Modeled after the official -tab1- command.
    */

    version 12
    syntax varlist(min=2 max=2 numeric) [if] [in] [, *]

    tokenize `varlist'

    tempvar prod
    gen `prod' = `1' * `2'
    label var `prod' "`1' x `2'"

    tempvar touse
    mark `touse' `if' `in'

    capture noisily tabulate `prod' if `touse', `options'

end

一些使用新定义的命令tabulate2的代码：

clear all
set more off

input ///
var1 var2
1 2
3 4
3 4
3 4
5 6
end

list

tabulate2 var1 var2

输出：

. tabulate2 var1 var2

var1 x var2 |      Freq.     Percent        Cum.
------------+-----------------------------------
          2 |          1       20.00       20.00
         12 |          3       60.00       80.00
         30 |          1       20.00      100.00
------------+-----------------------------------
      Total |          5      100.00

不完美，但我希望你明白这个想法。

另见help program及其中的参考资料。

制表动态创建的变量

1 个答案: