Question

以下代码尝试替换Groovy类中的现有方法：

class A {
  void abc()  {
     println "original"
  }
} 

x= new A()
x.abc()
A.metaClass.abc={-> println "new" }
x.abc()
A.metaClass.methods.findAll{it.name=="abc"}.each { println "Method $it"}

new A().abc()

它会产生以下输出：

original
original
Method org.codehaus.groovy.runtime.metaclass.ClosureMetaMethod@103074e[name: abc params: [] returns: class java.lang.Object owner: class A]
Method public void A.abc()
new

这是否意味着当通过将元类设置为闭包来修改元类时，它并不真正替换它，而只是添加了它可以调用的另一个方法，从而导致元类有两种方法？是否有可能真正替换方法，以便第二行输出打印“新”？

当试图找出它时，我发现DelegatingMetaClass可能有所帮助 - 这是最Groovy的方法吗？

Answer 1

您可以使用每个实例的metaClass来更改现有对象中的值，如下所示：

x= new A()
x.abc()
x.metaClass.abc={-> println "new" }
x.abc()
x.metaClass.methods.findAll{it.name=="abc"}.each { println "Method $it"}

但是正如你所看到的，x将有两个与之相关的方法（实际上，一个方法和你添加的闭包

如果更改A的定义，使方法成为闭包定义，如下所示：

class A {
  def abc = { ->
     println "original"  
  }
}

然后你只会在metaClass中获得一个闭包，并且在更改后没有方法

Answer 2

我完全同意@tim_yates的观点。但是，有一种解决方法，如果你想避免修改原始类而使用MethodClosure，如下所示：

class A {
  void abc()  {
     println "original"
  }
} 

x = new A()

//Create a Method Closure or Method pointer
pointer = x.&abc

//Replace Original call with Method pointer
//x.abc()
pointer()

//Meta classed
A.metaClass.abc={-> println "new" }

//Call method pointer instead of original again
//x.abc()
pointer()

A.metaClass.methods.findAll{it.name=="abc"}.each { println "Method $it"}

new A().abc()

你应该得到预期的结果：

original
new
Method org.codehaus.groovy.runtime.metaclass.ClosureMetaMethod@43094309
  [name: abc params: [] returns: class java.lang.Object owner: class A]
Method public void A.abc()
new

基于Groovy 2.2.1。问题太旧了。

Answer 3

我确定你的仍然有这个问题;）但是......我在Fedora 17上运行Groovy版本1.8.7。我发现你必须要做这个组合：

A.metaClass.abc = {-> println it}
A obj = new A()
obj.metaClass.abc = {-> println it}
obj.abc

从那以后它会按你的意愿行事。当你寻找方法时，你仍然会得到两个：

Method org.codehaus.groovy.runtime.metaclass.ClosureMetaMethod@103074e[name: abc params: [] returns: class java.lang.Object owner: class A]
Method public void A.abc()

但至少您不必更改public void声明。
不确定这是一个错误还是什么。

Answer 4

如果你只有运行时的实例：

// save original method
def savedAbcMetaMethod = A.metaClass.getMetaMethod('abc', [] as Class[])

// Override Abc Method
A.metaClass.abc = {
    // Do something else here
    // ...
    // Method is called on instance (provide context with delegate)
    savedAbcMetaMethod.invoke(delegate)
    // ...
    // Perhaps more code here
}

MetaMethod 关于 Groovy 文档。

我从here得出这个答案。

是否可以替换现有对象的groovy方法？

4 个答案: