Question

标题可能不是100％正确，但让我告诉你问题：

(defmacro nvp!
  [n width height]
  `(q/defsketch (symbol (str (name '~n) "-viewport" ))
                  :title (name '~n))

简而言之：有一个名为defsketch的宏（它是lib quil的一部分，但这并不重要）。它的签名基本上是defsketch [applet-name & options]，它会创建一些内容并将其绑定到名为applet-name的var。出于某种原因，我想将其包装到另一个宏中 - 除其他外 - 采用applet-name参数，将该名称扩展为applet-name-viewport并将其传递给defsketch。但是，我无法弄清楚如何正确地做到这一点（在上面的代码中使用macroexpand（(pprint (macroexpand(nvp test-name 500 500)))，我得到

(def(clojure.core/symbol (clojure.core/str (clojure.core/name 'my-namespace.core/test-name) "-viewport"))
 (quil.applet/applet
 :title (clojure.core/name 'my-namespace.core/test-name)))

(clojure.core/symbol (clojure.core/str (clojure.core/name 'my-namespace.core/test-name) "-viewport") - 这部分看起来不错，但是在将它传递给内部宏之前应该以某种方式进行评估......

Answer 1

您需要取消引用生成新符号的表单，而不是原始符号本身。

以下是如何使用内部宏的defn类似宏来完成此操作的一个小示例：

(defmacro mydefn
  [name & body]
  `(defn ~name ~@body))

(defmacro defnview
  [n & body]
  `(mydefn ~(symbol (str (name n) "-viewport")) ~@body))

;; OR

(defmacro defnview
  [n & body]
  (let [n (symbol (str (name n) "-viewport"))]
    `(mydefn ~n ~@body)))

示例：

(defnview foo [a] a)
;; => #'user/foo-viewport

(foo-viewport 1)
;; => 1

(macroexpand '(defnview foo [a] a))
;; => (def foo-viewport (clojure.core/fn ([a] a)))

另一个宏内的Clojure宏：如何从符号生成字符串

1 个答案: